Tartalom
Index 🔎︎

## WORKDAY.INTL

Returns the date calculated from a start date with a specific number of work days, before or after the start date. The calculation can include week-ends and holidays as non-working days.

This function is available since LibreOffice 4.3

#### Syntax

WORKDAY.INTL(StartDate; Days; Weekend; Holidays)

StartDate: is the date from when the calculation is carried out.

Days is the number of workdays. Positive value for a result after the start date, negative value for a result before the start date.

Weekend is an optional parameter – a number or a string used to specify the days of the week that are weekend days and are not considered working days. Weekend is a weekend number or string that specifies when weekends occur. Weekend number values indicate the following weekend days:

Number 1 to 7 for two-day weekends and 11 to 17 for one-day weekends.

Szám | Hétvége
1 or omitted | Szombat és vasárnap
2 | Sunday and Monday
3 | Monday and Tuesday
4 | Tuesday and Wednesday
5 | Wednesday and Thursday
6 | Thursday and Friday
7 | Friday and Saturday
11 | Sunday only
12 | Monday only
13 | Tuesday only
14 | Wednesday only
15 | Thursday only
16 | Friday only
17 | Saturday only

Weekend string provides another way to define the weekly non-working days. It must have seven (7) characters – zeros (0) for working day and ones (1) for non-working day. Each character represents a day of the week, starting with Monday. Only 1 and 0 are valid. “1111111” is an invalid string and should not be used. For example, the weekend string “0000011” defines Saturday and Sunday as non-working days.

Holidays is an optional list of dates that must be counted as non-working days. The list can be given in a cell range.

A dátumok képletek részeként való megadása során a dátumelválasztóként használt törtjelek és kötőjelek aritmetikai operátorként is értelmezhetők. Ennek következtében az adott formátumban megadott dátumok nem mindig dátumként kerülnek felismerésre, ami hibás számításokat eredményez. Ha biztosítani kívánja, hogy a dátumok ne a képlet részeként kerüljenek értelmezésre, akkor használja a DÁTUM függvényt (például: DÁTUM(1954;7;20)), vagy a dátumokat idézőjelek között, ISO 8601 jelöléssel adja meg (például "1954-07-20"). Kerülje a területi beállítástól függő dátumformátumokat (például: "07/20/54"), ilyenkor a számítás hibákat eredményezhet, ha a dokumentumot eltérő területi beállítással töltik be.

Unambiguous conversion is possible for ISO 8601 dates and times in their extended formats with separators. If a #VALUE! error occurs, then unselect Generate #VALUE! error in LibreOffice - Preferences Tools - Options - LibreOffice Calc - Formula, button Details... in section "Detailed Calculation Settings", Conversion from text to number list box.

#### Example

What date comes 20 workdays after December 13, 2016? Enter the start date in C3 and the number of workdays in D3.

The weekend parameter (number) may be left blank or defined as 1 for default weekend (non-working days) – Saturday and Sunday.

Cells F3 to J3 contain five (5) holidays for Christmas and New Year in date format: December 24, 2016; December 25, 2016; December 26, 2016; December 31, 2016; and January 1, 2017.

=WORKDAY.INTL(C3;D3;;F3:J3) returns January 11, 2017 in the result cell, say D6 (use date format for the cell).

To define Friday and Saturday as weekend days, use the weekend parameter 7.

=WORKDAY.INTL(C3;D3;7;F3:J3) returns January 15, 2017 with weekend parameter 7.

To define Sunday only the weekend day, use the weekend parameter 11.

=WORKDAY.INTL(C3;D3;11;F3:J3) returns January 9, 2017.

Alternatively, use the weekend string "0000001" for Sunday only weekend.

=WORKDAY.INTL(C3;D3;"0000001";F3:J3) returns January 9, 2017.

The function can be used without the two optional parameters – Weekday and Holidays – by leaving them out:

=WORKDAY.INTL(C3;D3) gives the result: January 10, 2017.

Kapcsolódó témakörök

NETWORKDAYS

NETWORKDAYS.INTL

WORKDAY

Date functions