Contingut
Índex 🔎︎

## DIFDATES

Aquesta funció retorna el nombre de dies, mesos o anys complets entre la data inicial i la data final.

This function is available since LibreOffice 3.6

### Sintaxi

DIFDATES(Data inicial; Data final; Interval)

Data inicial és la data a partir de la qual es duu a terme el càlcul.

Data final és la data fins a la qual es fa el càlcul. La Data final ha de ser posterior a la Data inicial.

Interval és una cadena, els valors acceptats són "d", "m", "y", "ym", "md" o "yd".

En introduir dates com a part de fórmules, les barres i guionets usats com a separadors s'interpreten com a operadors aritmètics. Per tant, les dates en aquest format no es reconeixen com a dates i produeixen càlculs erronis. Per a evitar que les dates s'interpreti com a part de fórmules, feu servir la funció DATA — p. ex. DATA(1954;7;20)—, o escriviu la data entre cometes i en la notació ISO 8601 —p. ex. "1954-07-20"—. Eviteu fer servir formats de data regionals, com ara «07/20/54», perquè això pot generar error si el document s'obre amb una configuració regional diferent.

Unambiguous conversion is possible for ISO 8601 dates and times in their extended formats with separators. If a #VALUE! error occurs, then unselect Generate #VALUE! error in LibreOffice - Preferences Tools - Options - LibreOffice Calc - Formula, button Details... in section "Detailed Calculation Settings", Conversion from text to number list box.

Valor d'«Interval» | Valor de retorn
"d" | Nombre de dies complets entre la Data inicial i la Data final.
"m" | Nombre de mesos complets entre la Data inicial i la Data final.
"y" | Nombre d'anys complets entre la Data inicial i la Data final.
"ym" | Nombre de mesos complets en restar els anys de la diferència entre la Data inicial i la Data final.
"md" | Nombre de dies complets en restar els anys i els mesos de la diferència entre la Data inicial i la Data final.
"yd" | Nombre de dies complets en restar els anys de la diferència entre la Data inicial i la Data final.

### Exemple

Càlcul de la data de naixement. Una persona va néixer el 17/04/1974. Avui és el 13/06/2012.

=DATEDIF("1974-04-17";"2012-06-13";"y") yields 38.

=DATEDIF("1974-04-17";"2012-06-13";"ym") yields 1.

=DATEDIF("1974-04-17";"2012-06-13";"md") yields 27.

So he is 38 years, 1 month and 27 days old.

=DATEDIF(DATE(1974,4,17);"2012-06-13";"m") yields 457, he has been living for 457 months.

=DIFDATES("17/04/1974";"13/06/2012";"d") dóna 13937. Per tant, ha viscut 13937 dies.

=DATEDIF("1974-04-17";DATE(2012;06;13);"yd") yields 57, his birthday was 57 days ago.