Indhold
Indholdsfortegnelse 🔎︎

# AGGREGER-funktion

Denne funktion returnerer et aggregeret resultat af beregningen i området. Du kan benytte forskellige aggregeringsfunktioner som oplistet herunder. Aggreger-funktionen giver dig mulighed for at udelade skjulte rækker, fejl, subtotaler og andre AGGREGER-funktioner i beregningen.

AGGREGER-funktionen bruges på lodrette områder af data med aktiveret AutoFilter. Hvis AutoFilter ikke er aktiveret vil automatisk genberegning af funktionen ikke virke for nyligt skjulte rækker. Det er ikke meningen at funktionen skal virke på vandrette områder, men kan godt bruges, dog med visse begrænsninger. Specielt vil AGGREGER-funktionen tilknyttet et vandret område ikke respektere at skjule kolonner, men undgår korrekt fejl og resultater af SUBTOTAL og andre AGGREGER-funktioner inde i rækken.

Denne funktion er tilgængelig siden LibreOffice4.4

### Syntaks

AGGREGER(Funktion; Valg; Ref1 [; Ref2 [; …]])

eller

AGGREGER(Funktion; Valg; Område [; k])

Funktion – obligatorisk argument. Et funktionsindeks eller en reference til en celle med værdi fra 1 til 19, jf. følgende tabel.

Funktionsindeks | Benyttet funktion
1 | MIDDEL
2 | TÆL
3 | TÆLV
4 | MAKS
5 | MIN
6 | PRODUKT (PRODUCT på engelsk)
7 | STDAFV.S
8 | STDAFV.P
9 | SUM
10 | VARIANS.S
11 | VARIANS.P
12 | MEDIAN
13 | HYPPIGST.ENKELT
14 | STØRSTE (LARGE på engelsk)
15 | MINDSTE (SMALL på engelsk)
16 | FRAKTIL.MEDTAG
17 | KVARTIL.MEDTAG
18 | FRAKTIL.UDELAD
19 | KVARTIL.UDELAD

Valg – obligatorisk argument. Et valgindeks eller reference til en celle med værdi fra 0 til 7 afgør hvad der skal ignoreres i funktionen.

Valg-indeks | Tilknyttet valg
0 | Ignorer kun indlejrede SUBTOTAL og AGGREGER-funktioner
1 | Ignorer kun skjulte rækker, indlejrede SUBTOTAL og AGGREGER-funktioner
2 | Ignorer kun fejl samt indlejrede SUBTOTAL og AGGREGER-funktioner
3 | Ignorer skjulte rækker, fejl samt indlejrede SUBTOTAL og AGGREGER-funktioner
4 | Ignorer intet
5 | Ignorer kun skjulte rækker
6 | Ignorer kun fejl
7 | Ignorer kun skjulte rækker og fejl

Ref1 – obligatorisk argument. Det første numeriske argument (hvis området er at af en liste af værdier inden i funktionen) eller en reference til en celle som indeholder den.

Ref2, 3, ... – valgfrie. Et numerisk argument eller en reference til en celle (op til 253 argumenter), for hvilke du vil beregne værdier.

Område – obligatorisk argument. Området kan defineres af grænserne i et område, navnet for et navngivet område eller kolonneetiketten.

For at bruge kolonneetiketten skal funktionen "Automatisk find kolonne- og rækkeetiketter" være aktiveret.

k – obligatorisk argument for følgende funktioner: STØRSTE, MINDSTE, KVARTIL.MEDTAG, KVARTIL.MEDTAG, FRAKTIL.UDELAD, KVARTIL.UDELAD. Det er et numerisk argument, som skal korrespondere med det andet argument i funktionerne.

### Eksempel

| A | B | C
1 | KolonneEt | KolonneTo | KolonneTre
2 | 34 | 11 | 12
3 | 10 | 56 | 35
4 | #DIV/0! | 5 | 3
5 | 20 | 8 | 1
6 | 0 | 8 | 9
7 | #VÆRDI! | 20 | 21
8 | 5 | 7 | 8
9 | 14 | 0 | 5

=AGGREGER(4;2;A2:A9)
Returnerer maksimum værdi for området A2:A9 = 34, hvor =MAKS(A2:A9) returnerer fejlen Err:511.

=AGGREGER(9;5;A5:C5)
Returnerer summen for området A5:C5 = 29, selv om nogle af kolonnerne er skjulte.

=AGGREGER(9;5;B2:B9)
Returner summen af kolonnen B = 115. Hvis nogen række er skjult vil funktionen se bort fra dens værdi, for eksempel hvis den syvende række er skjult, vil funktionen returnere 95.

Hvis du behøver at anvende funktionen med et 3D-område, viser dette eksempel, hvordan det gøres.

=AGGREGER(13;3;Ark1.B2:B9:Ark3.B2:B9)
Funktionen returnerer tilstand af værdierne af anden kolonne, fra arkene 1:3 (der har de samme data) = 8.

Du kan referere til en celle eller et område for hvert enkelt argument i formlen. Følgende eksempel viser hvordan. Desuden viser eksemplet at du kan bruge kolonneetiketter til at definere arealet.

=AGGREGER(E3;E5;'ColumnOne')
Hvis E3 = 13 og E5 = 5, så returnener funktionen tilstanden af den første kolonne = 10.

Relaterede emner

MIDDEL, TÆL, TÆLV, MAKS, MIN, PRODUKT, STDAFV.S, STDAFV.P, SUM, VARIANS.S, VARIANS.P, MEDIAN, HYPPIGST.ENKELT, STØRSTE, MINDSTE, FRAKTIL.MEDTAG , KVARTIL.MEDTAG, FRAKTIL.UDELAD, KVARTIL.UDELAD

Find kolonne og række etiketter automatisk