Edukiak
Indizea 🔎︎

# Kalkulu-orrietako funtzioak

Kalkulu-orria funtzioen deskribapenak eta adibideak aurkituko dituzu atal honetan.

Komando hau erabiltzeko...

Txertatu - Funtzioa - Kalkulu-orria kategoria

## ERROR.TYPE

Errore mota espezifiko bat ordezkatzen duen zenbaki bat ematen du, edo #E/E errore-balioa, errorerik ez badago.

## ADDRESS

Gelaxkaren erreferentzia ematen du testu moduan, zehaztutako errenkada- eta zutabe-zenbakien arabera. Nahi izanez gero, erreferentzia nola interpretatuko den defini dezakezu: helbide absolutu gisa (adib. $A$1), helbide erlatibo gisa (A1), edo modu mistoan (A$1 edo $A1). Orriaren izena ere zehatz dezakezu.

Elkarrerabilgarriak izan daitezen, ADDRESS eta INDIRECT funtzioek parametro gehigarri bat onartzen dute, ohiko A1 notazioaren ordez R1C1 helbide-notazioa erabiliko den edo ez zehazteko.

ADDRESS funtzioan, parametroa laugarren parametro gisa sartzen da, aukerako orri-izenaren parametroa bosgarren lekura eramanez.

INDIRECT funtzioan, parametroa bigarren parametro gisa txertatzen da.

Bi funtzioetan, argumentua 0 balioarekin txertatzen bada, orduan R1C1 notazioa erabiliko da. Argumentua ez bada zehazten edo 0 ez den balio bat badauka, orduan A1 notazioa erabiliko da.

R1C1 notazioaren kasuan, ADDRESS funtzioak '!' orri-izenen bereizle gisa erabiliz ematen ditu helbide-kateak, eta INDIRECT funtzioak harridura-marka erabiltzea espero du orri-izenen bereizle gisa. Bi funtzioek puntua ('.') erabiltzen dute orri-izenen bereizle gisa A1 notazioarekin.

ODF 1.0/1.1 formatuko dokumentuak irekitzean, orri-izena laugarren parametro gisa erakusten duten ADDRESS funtzioek orri-izen hori bosgarren parametro izateko mugituko dute. 1 balioa daukan laugarren parametro bat txertatuko da.

Dokumentu bat ODF 1.0/1.1 formatuan gordetzean, ADDRESS funtzioak laugarren parametro bat badauka, parametro hori kendu egingo da.

Ez gorde kalkulu-orria ODF 1.0/1.1 formatu zaharrean, ADDRESS funtzioaren laugarren parametro berria 0 balioarekin erabili bada.

INDIRECT funtzioa ODF 1.0/1.1 formaturako bihurketarik gabe gordeko da. Bigarren parametroa hor bazegoen, Calc-en bertsio zaharragoek errorea emango dute funtzio horrekin.

### Sintaxia

ADDRESS(Errenkada; Zutabea; Abs; A1; "Orria")

Errenkada: gelaxka-erreferentziaren errenkada-zenbakia

Zutabea: gelaxka-erreferentziaren zutabe-zenbakia (letra ez)

Abs argumentuak erreferentzia mota zehazten du:

1: absolutua ($A$1)

2: errenkada-erreferentziaren mota absolutua da; zutabe-erreferentzia, aldiz, erlatiboa (A$1)

3: errenkada (erlatiboa); zutabea (absolutua) ($A1)

4: erlatiboa (A1)

A1 (aukerakoa) - 0 ezartzen bada, R1C1 notazioa erabiliko da. Parametro hori ez bada agertzen edo 0 ez den beste balio bat ezarri bazaio, A1 notazioa erabiliko da.

Orria: orriaren izena adierazten du. Komatxo bikoitzen artean ipini behar da.

### Adibidea:

=ADDRESS(1;1;2;;"Orria2") formulak hau ematen du: Orria2.A$1

Goiko formula uneko orriaren B2 gelaxkan badago, eta 2. orriko A1 gelaxkak -6 balioa badu, gelaxka horri zeharkako erreferentzia egin diezaiokezu B2 gelaxkan funtzio bat ipinita, =ABS(INDIRECT(B2)) sartuta. Emaitza izango da B2 gelaxkan zehaztutako gelaxka-erreferentziaren balio absolutua; kasu honetan, 6.

## AREAS

Barruti anizkoitz batean zenbat barruti dauden ematen du.. Barruti bat ondoz ondoko gelaxken barrutia edo gelaxka bakarra izan daiteke.

Funtzio honek argumentu bakar bat espero du. Hainbat barruti zehazten badituzu, parentesi gehigarrien artean jarri behar dituzu. Hainbat barruti sar ditzakezu puntu eta koma (;) bereizle gisa erabiliz, baina hori automatikoki bihurtzen da tilet (~) eragile. Tiletak barrutiak elkartzeko erabiltzen dira.

### Sintaxia

AREAS(Erreferentzia)

Erreferentzia: gelaxka baten edo gelaxka-barruti baten erreferentzia.

### Adibidea

=AREAS((A1:B3;F2;G1)): 3 ematen du, hiru gelaxkaren/barrutiaren erreferentzia baita. Ondoren, sarrera honen arabera bihurtuko da: =AREAS((A1:B3~F2~G1)).

=AREAS(All) funtzioak 1 emango du, aurretik Datuak - Definitu barrutia aukeran area bat definitu baduzu.

## CHOOSE

Balio bat aukeratzen du gehienez 30 balio-argumentu dituen zerrenda batetik.

### Sintaxia

CHOOSE(Indizea; balioa 1;...balioa 30)

Indizea: 1 eta 30 bitarteko erreferentzia edo zenbaki bat da, zerrendatik zein balio hartu behar duen adierazten duena.

Balioa1, Balioa2, ..., Balioa30: gelaxka-erreferentzia edo balio indibidual gisa sartutako balioen zerrenda.

### Adibidea

=CHOOSE(A1;B1;B2;B3;"Gaur";"Bihar";"Bihar") formulak, adibidez, B2 gelaxkaren balioa itzuliko du 'A1 = 2'rentzat; 'A1 = 4'rentzat, aldiz, funtzioak "Gaur" testua emango du.

## COLUMN

Erreferentzia baten barruko zutabe-zenbakia ematen du. Erreferentzia gelaxka bat bada, Erreferentzia gelaxka bada, gelaxkaren zutabe-zenbakia emango du; parametroa gelaxka-barrutia bada, dagozkion zutabe-zenbakiak emango ditu lerro bakarreko matrizearen bidez, baldin eta formula matrize-formula gisa sartu bada. Barruti-erreferentziaren parametro bat duen COLUMN funtzioa ez bada matrize-formula batentzat erabili, barrutiko lehen gelaxkaren zutabe-zenbakia bakarrik zehaztuko da.

### Sintaxia

COLUMN(erreferentzia)

Erreferentzia: lehen zutabearen zenbakia zehaztu behar zaion gelaxkaren erreferentzia.

Erreferentziarik sartzen ez bada, formula sartutako gelaxkaren zutabe-zenbakia aurkituko du. LibreOffice Calc-ek automatikoki ezartzen dio erreferentzia uneko gelaxkari.

### Adibidea

=COLUMN(A1) berdin 1. A zutabea da taulako lehen zutabea.

=COLUMN(C3:E3) berdin 3. C zutabea da taulako hirugarren zutabea.

=COLUMN(D3:G10) funtzioak 4 ematen du; izan ere, D zutabea taulako laugarren zutabea da eta COLUMN funtzioa ez da erabiltzen matrize-formula gisa. (Horrelakoetan, beti matrizearen lehen balioa erabiltzen da emaitza gisa).

{=COLUMN(B2:B7)} eta =COLUMN(B2:B7) biek 2 itzultzen dute, erreferentziak soilik B zutabea daukalako taulako bigarren zutabe gisa. Zutabe bakarreko areek soilik zutabearen zenbaki bakarra dutenez, berdin dio formula formula-matrize gisa erabiltzen den edo ez.

=COLUMN(): 3 ematen du, formula C zutabean sartu bada.

{=COLUMN(Untxia)}: errenkada bakarreko matrizea (3, 4) ematen du, "Untxia" bada barruti izenduna (C1:D3).

## COLUMNS

Erreferentziaren zutabe kopurua ematen du.

### Sintaxia

COLUMNS(matrizea)

Matrizea: zutabe kopuru totala kalkulatu behar zaion gelaxka-barrutiaren erreferentzia. Argumentua gelaxka bakarra ere izan daiteke.

### Adibidea

=COLUMNS(B5): 1 ematen du, gelaxka batek zutabe bakarra baitu.

=COLUMNS(A1:C5) 3 ematen du. Erreferentziak hiru zutabe ditu.

=COLUMNS(Untxia): 2 ematen du Untxia bada barruti izenduna (C1:D3).

## DDE

DDE esteka baten emaitza ematen du. Estekatutako barrutiko edo ataleko edukia aldatzen bada, emaitzaren balioa ere aldatu egingo da. Eguneratutako estekak ikusteko, berriro kargatu behar duzu kalkulu-orria, edo Editatu - Estekak aukeratu. Plataformen arteko estekak ez dira onartzen; adibidez, Windows makina batean exekutatzen ari den LibreOffice instalazio batetik Linux makina batean sortutako dokumentu batera.

### Sintaxia

DDE(Zerbitzaria;Fitxategia;Barrutia;Modua)

Zerbitzaria: zerbitzari-aplikazioaren aukera da. LibreOfficeaplikazioek "soffice" zerbitzari-izena izaten dute.

Fitxategia: fitxategi-izen osoa, bide-izena zehaztuta.

Barrutia: ebaluatu beharreko datuen barrutia.

Modua: DDE zerbitzariak datuak zenbaki nola bihurtzen dituen kontrolatzeko aukerako parametroa.

Modua | Efektua
0 edo ezer ez | Zenbaki-formatua gelaxka-estilo "lehenetsitik"
1 | Datuak beti interpretatzen dira AEBetako ingelesaren formatu estandarrean
2 | Datuak testu gisa maneiatzen dira; ez dira zenbaki-formatura bihurtzen

### Adibidea

=DDE("soffice";"c:\office\document\data1.ods";"Orria1.A1") funtzioak LibreOffice Calc-en data1.ods kalkulu-orriko Orria1 orriko A1 gelaxkako edukia irakurtzen du.

=DDE("soffice";"c:\office\document\motto.odt";"Today's motto") funtzioak lema bat ematen du formula honen gelaxkan. Lehendabizi, motto.odt dokumentuan lerro bat sartu behar duzu lemaren testua duena; ondoren, Today’s Motto (Gaurko Lema) izeneko sekzioko lehen lerro gisa definitu behar da (LibreOffice Writerren, Txertatu - Sekzioa aukeran). Lema aldatzen (eta gordetzen) bada LibreOffice Writer dokumentuan, lema hori eguneratu egingo da DDE esteka hori definituta duten LibreOffice Calc fitxategiaren gelaxka guztietan.

## ERRORTYPE

Gelaxka batean gertatutako errore bati dagokion errore-balioa ematen du. Zenbaki horren laguntzarekin, errore-mezuaren testua sor dezakezu.

Errorea gertatzen bada, balio logiko bat edo zenbakizko bat emango du funtzioak.

Errorea duen gelaxkan klik egiten baduzu, LibreOffice(r)en errore-kode aurredefinitua agertuko da egoera-barran.

### Sintaxia

ERRORTYPE(Erreferentzia)

Erreferentzia: errorea gertatzen den gelaxkaren helbidea.

### Adibidea

A1 gelaxkak Err:518 bistaratzen badu, =ERRORTYPE(A1) funtzioak 518 zenbakia ematen du.

## GETPIVOTDATA

GETPIVOTDATA funtzioak taula dinamiko baten emaitza-balioa itzultzen du. Balioa eremuen eta elementuen izenen bidez adierazten da, beraz baliozkoa da taula dinamikoaren diseinua aldatzen bada ere.

### Sintaxia

Bi sintaxi-definizio desberdin erabil daitezke:

GETPIVOTDATA(HelburuEremua; TaulaDinamikoa; [ 1. eremua; 1. elementua; ... ])

GETPIVOTDATA(TaulaDinamikoa; Murriztapenak)

Bigarren sintaxia erabiliko da, bi parametro berdin ematen badira, eta horietatik lehen parametroa gelaxka edo gelaxka-barruti baten erreferentzia bada. Lehen sintaxia erabiliko da beste kasu guztietan. Funtzioen morroiak lehen sintaxia erakutsiko du.

### Sintaxia

HelburuEremua taula dinamikoko datu-eremu bat hautatzen duen kate bat da. Katea iturburu-zutabearen izena izan daiteke, edo taulan erakusten den datu-eremuaren izena (esaterako "Batuketa - Salmentak").

TaulaDinamikoa taula dinamiko batean kokatuta dagoen edo taula dinamiko bat duen gelaxka baten edo gelaxka-barruti baten erreferentzia da. Gelaxka-barrutiak taula dinamiko bat baino gehiago badu, sortutako azken taula erabiliko da.

n. eremua / n. elementua bikoterik ematen ez bada, total orokorra itzuliko da. Bestela, bikote bakoitzak emaitzak bete behar duen murriztapen bat gehituko du. n. eremua taula dinamikoko eremu baten izena da. n. elementua eremu horretako elementu baten izena da.

Taula dinamikoak murriztapen guztiak betetzen dituen emaitza bakarra badu, edo bat datozen balio guztiak laburbiltzen dituen emaitza subtotal bat badu, emaitza hori itzuliko da. Bat datorren emaitzarik ez badago, edo subtotala duten hainbat badaude, errore bat itzuliko da. Baldintza horiek taula dinamikoan sartuta dauden emaitzei aplikatzen zaizkie.

Iturburu-datuek taula dinamikoaren ezarpenen bidez ezkutatutako sarrerak badituzte, horiek ez ikusi egingo dira. Eremua/elementua bikotearen ordena ez da esanguratsua. Eremuen eta elementuen izenetan ez dira maiuskulak eta minuskulak bereizten.

Orrialde-eremu baterako murriztapenik ematen ez bada, eremuan hautatutako balioa erabiliko da. Orrialde-eremu baterako murriztapen bat ematen bada, eremuan hautatutako balioarekin bat etorri behar du, bestela errorea itzuliko da. Orrialde-eremuak taula dinamikoaren goian ezkerrean dauden eremuak dira, taula dinamikoaren diseinu-koadroko "Orrialde-eremuak" area erabilita betetzen direnak. Orrialde-eremu bakoitzerako, elementu (balio) bat hautatu daiteke, alegia, elementu hori besterik ez da sartuko kalkuluan.

Taula dinamikoko balio subtotalak "auto" funtzioa badarabilte soilik erabiliko dira (murriztapenean adierazita dagoenean salbu, ikusi Bigarren sintaxia behean).

### Sintaxia

TaulaDinamikoa balioak lehen sintaxian duen esanahi bera du.

Murriztapenak: zuriunez bereizitako zerrenda bat da. Sarrerak komatxo (komatxo bakun) artean jar daitezke. Karaktere-kate osoa komatxoen (komatxo bikoitzen) artean jarri behar da, beste gelaxka bateko karaktere-katea erreferentziatzen ez baduzu.

Sarreretako bat datu-eremuaren izena izan daiteke. Datu-eremuaren izena kanpoan utzi daiteke taula dinamikoak datu-eremu bakarra badu, bestela presente egon behar du.

Gainerako sarreretako bakoitzak murriztapen bat zehazten du, Eremua[Elementua] forman ([ eta ] karaktere literalekin), edo soilik Elementua, elementu-izena bakarra bada taula dinamikoak darabiltzan eremu guztien artean.

Funtzio-izen bat Eremua[Elementua;Funtzioa] gisa gehi daiteke, eta horrek funtzio hori erabiltzen duten subtotal-balioekin bakarrik bat etortzera behartuko du murriztapena. Funtzio-izen posibleak: Sum, Count, Average, Max, Min, Product, Count (zenbakiak soilik), StDev (lagina), StDevP (populazioa), Var (lagina) eta VarP (populazioa), maiuskulak/minuskulak bereizi gabe.

## HLOOKUP

Balio bat bilatzen du eta hautatutako barrutiaren azpiko gelaxkei erreferentzia egiten die. Matrize baten lehen errenkadak balio jakin bat duen egiaztatzen du funtzio honek. Orduan funtzioak matrizearen errenkada batean ematen du balioa. Indizea aukerak esleitzen du errenkada, matrizearen zutabe berean.

Bilaketak adierazpen erregularrak onartzen ditu. Esaterako, "dena.* sartu dezakezu, "dena" hitza edozein karaktere kopururekin jarraituta aurkitu nahi baduzu. Adierazpen erregularra ere baden testuren bat bilatu nahi baduzu, karaktere bakoitzari "\" karaktere bat idatzi behar diozu aurrean. Adierazpen erregularren ebaluazio automatikoa aktibatu eta desaktibatu dezakezu LibreOffice - Hobespenak Tresnak - Aukerak - LibreOffice Calc - Kalkulatu atalean.

### Sintaxia

HLOOKUP(bilaketa_irizpidea;matrizea;indizea;ordenatuta)

Ikus baita ere: VLOOKUP (zutabeak eta errenkadak aldatu egiten dira)

Gelaxka hutsen kudeaketa

## HYPERLINK

HYPERLINK funtzioa daukan gelaxka batean klik egitean, hiperesteka ireki egingo da.

Aukerako gelaxka-testua parametroa erabiltzen baduzu, formulak URLa lokalizatzen du, eta ondoren testua edo zenbakia erakusten du.

Hiperestekatutako gelaxka bat teklatuarekin irekitzeko, hautatu gelaxka, sakatu F2 editatze moduan sartzeko, eraman kurtsorea hiperestekaren aurrera, sakatu ⇧+F10, eta ondoren aukeratu Ireki hiperesteka.

### Sintaxia

HYPERLINK (URL) edo HYPERLINK (URLa;gelaxka-testua)

URLa: estekaren testua zehazten du. Aukerako gelaxka-testua parametroa da gelaxkan bistaratuko den testua edo zenbakia, eta emaitza gisa emango dena. Gelaxka-testua parametroa ez bada zehazten, URLa bistaratuko da gelaxkan, eta horixe bera emango da emaitza gisa.

0 zenbakia emango da gelaxka hutsei eta matrize-elementuei dagokienez.

### Adibidea

=HYPERLINK("http://www.example.org"): "http://www.example.org" testua erakutsiko du gelaxkan eta http://www.example.org esteka exekutatuko du klik egindakoan.

=HYPERLINK("http://www.example.org";"Egin klik hemen") funtzioak "Egin klik hemen" testua erakutsiko du gelaxkan eta http://www.example.org esteka exekutatuko du klik egindakoan.

=HYPERLINK("http://www.example.org";12345): 12345 zenbakia bistaratuko du eta http://www.example.org hiperesteka exekutatuko du klik egindakoan.

=HYPERLINK($B4): B4 gelaxkak http://www.example.org izango du. Funtzioak "http://www.example.org" gehituko dio hiperesteka-gelaxkaren URLari, eta testu bera itzuliko du, formularen emaitzan erabiliko dena, hain zuzen.

=HYPERLINK("http://www.";"egin klik") & "example.org": 'egin klik' testuak adibidea.org testua erakutsiko du gelaxkan eta http://www.example.org esteka exekutatuko du klik egindakoan.

=HYPERLINK("#Orria1.A1";"Joan hasierara"): Joan hasierara testua bistaratuko du, eta dokumentuko Orria1.A1 gelaxkara salto egingo du.

=HYPERLINK("file:C:/writer.odt#Specification";"Joan Writer laster-markara"): 'Joan Writer laster-markara' testua bistaratuko du, zehaztutako testu-dokumentua kargatuko du, eta 'Specification' laster-markara salto egingo du.

## INDEX

INDEX funtzioak barruti jakin bateko gelaxka baten edukia ematen du, errenkada- eta zutabe-zenbakiak edo aukerako barruti-izena zehaztuta.

### Sintaxia

INDEX(Erreferentzia;Errenkada;Zutabea;Barrutia)

Erreferentzia: erreferentzia bat da, zuzenean edo barruti-izena zehaztuz sartua. Barruti anizkoitzak baditu erreferentziak, erreferentzia edo barruti-izena parentesi artean adierazi behar da.

Errenkada (aukerakoa): balioa zehazteko erreferentzia-barrutiaren errenkada-indizea adierazten du. Zero bada (errenkada zehatzik ez), erreferentziatutako errenkada guztiak emango dira.

Zutabea (aukerakoa): balioa zehazteko erreferentzia-barrutiaren zutabe-indizea adierazten du. Zero bada (zutabe zehatzik ez), erreferentziatutako zutabe guztiak emango dira.

Barrutia (aukerakoa): erreferentzian barruti anizkoitza adierazi bada, azpibarrutiaren indizea adierazten da hemen.

### Adibidea

=INDEX(Prezioak;4;1): Datuak - Definitu aukeran Prezio gisa zehaztutako datu-baseko barrutiko 4. errenkadako eta 1. zutabeko balioa ematen du.

=INDEX(SumX;4;1): 4. errenkadako eta 1. zutabeko SumX barrutiko balioa ematen du, Orria - Izendatutako barrutiak eta adierazpenak - Definitu aukeran zehaztuta bezala.

=INDEX(A1:B6;1): A1:B6 barrutiko lehen errenkadaren erreferentzia bat ematen du.

=INDEX(A1:B6;0;1): A1:B6 barrutiko lehen zutabearen erreferentzia bat ematen du.

=INDEX((multi);4;1)-ek (anitz) barrutiko 4 lerroko eta 1 zutabeko balioa adierazten du, non zuk izendatu duzun Orriak - Izendatutako barrutiak eta adierazpenak - Definitu barruan multi bezala. Barruti anitza barruti laukizuzen ugariz osatu daiteke, bakoitza 4 lerro bat eta 1 zutabe batekin. Barruti anitz honetako bigarren blokea erabili nahi baduzu, sartu ezazu 2 zenbakia range parametro modura.

=INDEX(A1:B6;1;1): A1:B6 barrutiko goi-ezkerraldeko gelaxkako balioa adierazten du.

=INDEX((multi);0;0;2): barruti anizkoitzeko bigarren barrutiaren erreferentzia ematen du.

## INDIRECT

Testu-kate batek zehaztutako erreferentzia ematen du. Kate baten barrutia emateko ere erabil daiteke funtzio hau.

Elkarrerabilgarriak izan daitezen, ADDRESS eta INDIRECT funtzioek parametro gehigarri bat onartzen dute, ohiko A1 notazioaren ordez R1C1 helbide-notazioa erabiliko den edo ez zehazteko.

ADDRESS funtzioan, parametroa laugarren parametro gisa sartzen da, aukerako orri-izenaren parametroa bosgarren lekura eramanez.

INDIRECT funtzioan, parametroa bigarren parametro gisa txertatzen da.

Bi funtzioetan, argumentua 0 balioarekin txertatzen bada, orduan R1C1 notazioa erabiliko da. Argumentua ez bada zehazten edo 0 ez den balio bat badauka, orduan A1 notazioa erabiliko da.

R1C1 notazioaren kasuan, ADDRESS funtzioak '!' orri-izenen bereizle gisa erabiliz ematen ditu helbide-kateak, eta INDIRECT funtzioak harridura-marka erabiltzea espero du orri-izenen bereizle gisa. Bi funtzioek puntua ('.') erabiltzen dute orri-izenen bereizle gisa A1 notazioarekin.

ODF 1.0/1.1 formatuko dokumentuak irekitzean, orri-izena laugarren parametro gisa erakusten duten ADDRESS funtzioek orri-izen hori bosgarren parametro izateko mugituko dute. 1 balioa daukan laugarren parametro bat txertatuko da.

Dokumentu bat ODF 1.0/1.1 formatuan gordetzean, ADDRESS funtzioak laugarren parametro bat badauka, parametro hori kendu egingo da.

Ez gorde kalkulu-orria ODF 1.0/1.1 formatu zaharrean, ADDRESS funtzioaren laugarren parametro berria 0 balioarekin erabili bada.

INDIRECT funtzioa ODF 1.0/1.1 formaturako bihurketarik gabe gordeko da. Bigarren parametroa hor bazegoen, Calc-en bertsio zaharragoek errorea emango dute funtzio horrekin.

### Sintaxia

INDIRECT(Erref; A1)

Erref: gelaxka edo barruti baten erreferentzia (testu-formakoa).

A1 (aukerakoa) - 0 ezartzen bada, R1C1 notazioa erabiliko da. Parametro hori ez bada agertzen edo 0 ez den beste balio bat ezarri bazaio, A1 notazioa erabiliko da.

Kate-funtzioetatik kalkulatutako zeharkako helbideak erabiltzen dituen Exceleko kalkulu-orri bat irekitzen baduzu, orri-helbideak ez dira automatikoki itzuliko. Adibidez, INDIRECT("[filename]sheetname!"&B1) funtzioko Excel helbidea ez da bihurtuko INDIRECT("filename#sheetname."&B1) funtzioko Calc helbide.

### Adibidea

=INDIRECT(A1) berdin izango da, A1 gelaxkak C108 badauka erreferentzia gisa, eta C108 gelaxkak 100 balioa badauka.

Errenkada 1 eta zutabea 3 elementuen bidez definitutako gelaxkatik A1 gelaxkarainoko barrutiko gelaxka guztiak batzen ditu =SUM(INDIRECT("a1:" & ADDRESS(1;3))) funtzioak. Beraz, A1:C1 barrutia batzen da.

## LOOKUP

Gelaxka baten edukia ematen du errenkada bateko nahiz zutabe bateko barruti batetik edo matrize batetik. Nahi izanez gero, esleitutako balioa (indize berekoa) beste errenkada eta zutabe baten emango da. VLOOKUP eta HLOOKUP funtzioetan ez bezala, bilaketa eta emaitza bektoreak kokagune desberdinetan egon daitezke; ez dute zertan ondoz ondokoak izan. Gainera, LOOKUP funtzioaren bilaketa-bektoreak ordenatuta egon behar du, bestela bilaketak ez baitu emaitza erabilgarririk emango.

LOOKUP funtzioak ezin badu bilaketa-irizpidea aurkitu, bilaketa-irizpidea baino txikiagoa edo berdina den balio handiena hartzen du bilaketa-bektorean.

Bilaketak adierazpen erregularrak onartzen ditu. Esaterako, "dena.* sartu dezakezu, "dena" hitza edozein karaktere kopururekin jarraituta aurkitu nahi baduzu. Adierazpen erregularra ere baden testuren bat bilatu nahi baduzu, karaktere bakoitzari "\" karaktere bat idatzi behar diozu aurrean. Adierazpen erregularren ebaluazio automatikoa aktibatu eta desaktibatu dezakezu LibreOffice - Hobespenak Tresnak - Aukerak - LibreOffice Calc - Kalkulatu atalean.

### Sintaxia

LOOKUP(Bilaketa-irizpidea;bilaketa-bektorea;emaitza_bektorea)

Bilaketa-irizpidea: bilatu beharreko balioa, zuzenean nahiz erreferentzia gisa sartuta.

Bilaketa-bektorea errenkada- edo zutabe-bakunaren bilatzeko barrutia da.

Emaitza_bektorea: zutabe edo errenkada bakarreko beste barruti bat da; hortik hartzen da, hain zuzen, funtzioaren emaitza. Bilaketa-bektorean aurkitutako elementuaren indize bera duen emaitza-bektorearen gelaxka da emaitza.

Gelaxka hutsen kudeaketa

### Adibidea

=LOOKUP(A1;D1:D100;F1:F100): A1 gelaxkan sartu duzun zenbakiari D1:D100 barrutian dagokion gelaxka bilatzen du. Bilatutako balioari dagokionez, indizea zehazten da. Adib.: gelaxka honetako 12. gelaxka. Orduan, 12. gelaxkaren edukia emango du funtzioaren balio gisa (emaitzen bektorean).

## MATCH

Balioak konparatu ondoren, matrizean zenbatgarren kokagunea duen adierazten du. Bilaketan aurkitutako balioaren kokagunea ematen du funtzioak.

### Sintaxia

MATCH(Bilaketa-irizpidea;bilaketa_matrizea;mota)

Bilaketa-irizpidea: errenkada edo zutabe bakarreko matrizean bilatu beharreko balioa.

Bilaketa_matrizea: bilatutako erreferentzia da. Bilaketa-matrizea errenkada edo zutabe bakarreko matrizea izan daiteke, edo errenkada edo zutabe bakarreko zati bat.

Mota: 1, 0, edo –1 balioa izan dezake. Mota = 1 bada edo aukerako parametro hau ez bada agertzen, orduan ulertuko da bilaketa-matrizeko lehen zutabea goranzko ordenan ordenatuta dagoela. Mota= -1 bada, zutabeak beheranzko ordena duela ulertuko da. Microsoft Exceleko funtzio berari dagokio.

Mota = 0 bada, zehatz-mehatz bat datozen balioak bakarrik aurkituko ditu. Bilaketa-irizpidea behin baino gehiagotan bilatzen bada, aurrena bilatutakoa emango du funtzioak. Mota = 0 bada bakarrik bilatu ahal izango dituzu adierazpen erregularrak.

Mota = 1 bada edo hirugarren parametrorik ez badago, bilaketa-irizpidearen berdina edo txikiagoa den azken balioa emango du. Bilaketa-matrizea ordenatu gabe dagoenean aplikatzen da hau. Mota = -1 denean, handiagoa edo berdina den lehen balioa ematen du.

Bilaketak adierazpen erregularrak onartzen ditu. Esaterako, "dena.* sartu dezakezu, "dena" hitza edozein karaktere kopururekin jarraituta aurkitu nahi baduzu. Adierazpen erregularra ere baden testuren bat bilatu nahi baduzu, karaktere bakoitzari "\" karaktere bat idatzi behar diozu aurrean. Adierazpen erregularren ebaluazio automatikoa aktibatu eta desaktibatu dezakezu LibreOffice - Hobespenak Tresnak - Aukerak - LibreOffice Calc - Kalkulatu atalean.

### Adibidea

=MATCH(200;D1:D100): 200 balioa bilatzen du D1:D100 barrutian, zeina D zutabearen arabera ordenatuta baitago. Balio hori bilatu orduko, balioaren errenkada-zenbakia ematen du. Zutabean bilaketa egitean balio handiago bat aurkitzen bada, aurreko errenkadaren zenbakia ematen du.

## OFFSET

Abiapuntutik lerratutako gelaxkaren erreferentzia ematen du.

### Sintaxia

OFFSET(erreferentzia;errenkadak;zutabeak;altuera;zabalera)

Erreferentzia: erreferentzia horretatik abiatuta bilatzen du funtzioak erreferentzia berria.

Errenkadak: erreferentzia gorantz (balio negatiboa) edo beherantz zuzendu beharreko errenkada kopurua.

Zutabeak: erreferentzia ezkerrerantz (balio negatiboa) edo eskumarantz zuzendu beharreko zutabe kopurua. Erabili 0 zutabe berean geratzeko.

Altuera (aukerakoa): erreferentzia-kokagune berrian hasten den barruti baten aukerako altuera bertikala.

Zabalera (aukerakoa): erreferentzia-kokagune berrian hasten den barruti baten aukerako zabalera horizontala.

Errenkadak eta Zutabeak argumentuek ez dute errenkada edo zutabeen kopuru negatibo edo zero kopurura eraman behar.

Altuera eta Zabalera argumentuek ez dute errenkada edo zutabeen kopuru negatibo edo zero kopurura eraman behar.

LibreOffice Calc-eko funtzioetan, "aukerakoa" marka daukaten parametroak alde batera utz daitezke ondoren parametrorik ez dagoenean soilik. Adibidez, lau parametro dituen funtzio batean, funtzio horietako azken biek "aukerakoa" marka badaukate, 4. parametroa edo 3. eta 4. parametroa alde batera utz ditzakezu, baina ezin duzu alde batera utzi 3. parametroa bakarrik.

### Adibidea

=OFFSET(A1;2;2): C3 gelaxkako balioa ematen du (A1 gelaxka bi errenkada eta bi zutabe beherantz mugituta). C3 gelaxkak 100 balioa badauka, funtzio honek 100 balioa ematen du.

=OFFSET(B2:C3;1;1): B2:C3 barrutia errenkada bat beherago eta zutabe bat eskuinerago (C3:D4).

=OFFSET(B2:C3;-1;-1): B2:C3 barrutia errenkada bat gorago eta zutabe bat ezkerrerago (B2:D4).

=OFFSET(B2:C3;0;0;3;4): B2:C3 barrutiaren erreferentzia bat ematen du, baina tamaina aldatuta 3 errenkada eta 4 zutabe izan ditzan (B2:E4).

=OFFSET(B2:C3;1;0;3;4): B2:C3 barrutiaren erreferentzia bat ematen du, baina errenkada bat beherago, tamaina aldatuta 3 errenkada eta 4 zutabe izan ditzan (B3:E5).

=SUM(OFFSET(A1;2;2;5;6)): C3 gelaxkan hasten den eta 5 errenkadako altuera eta 6 zutabeko zabalera dituen barruti osoa zehazten du, hau da, C3:H7 barrutia.

Zabalera edo altuera sartzen bada, OFFSET funtzioak barruti bat itzuliko du eta, beraz, matrize-formula gisa sartu behar da. Zabalera eta altuera falta badira, gelaxka-erreferentzia bat itzuliko da.

## ROW

Erreferentzia baten barruko errenkada-zenbakia ematen du. Erreferentzia gelaxka bat bada, gelaxkaren errenkada-zenbakia ematen du. Erreferentzia gelaxka-barruti bat bada, dagozkion errenkada-zenbakiak ematen ditu zutabe bateko matrize batean, baldin eta formula matrize-formula gisa sartu bada. Barruti-erreferentzia batekin ROW funtzioa ez bada erabili matrize-formula batean, lehen barruti-gelaxkaren errenkada-zenbakia bakarrik emango du.

### Sintaxia

ROW(erreferentzia)

Erreferentzia: gelaxka, barrutia, edo barruti-izena da.

Erreferentzia bat adierazten ez baduzu, formula sartutako gelaxkaren errenkada-zenbakia emango du. LibreOffice Calc-ek automatikoki ezartzen dio erreferentzia uneko gelaxkari.

### Adibidea

=ROW(B3): 3 ematen du, erreferentziak taulako hirugarren errenkadari egiten baitio erreferentzia.

{=ROW(D5:D8)}: zutabe bakarreko matrizea ematen du (5, 6, 7, 8), zehaztutako erreferentziak 5 eta 8 arteko errenkadak baititu.

=ROW(D5:D8): 5 ematen du, ROW funtzioa ez baita erabili matrize-formula gisa, eta erreferentziaren lehen errenkadaren zenbakia bakarrik ematen du.

{=ROW(A1:E1)} eta =ROW(A1:E1) funtzioek 1 ematen dute, erreferentziak errenkada1 bakarrik baitu taulako lehen errenkada gisa. (Errenkada bakarreko areek errenkada-zenbaki bakarra izaten dutenez, berdin da formula matrize-formula gisa sartu ala ez).

=ROW(): 3 ematen du, formula 3. errenkadan sartu bada.

{=ROW(Untxia)}: zutabe bakarreko matrizea (1, 2, 3) ematen du, "Untxia" bada barruti izenduna (C1:D3).

## ROWS

Matrize edo erreferentzia batek zenbat errenkada dituen ematen du.

### Sintaxia

ROWS(matrizea)

Matrizea: errenkada kopuru totala kalkulatu behar zaion barruti izenduna edo erreferentzia.

### Adibidea

=Rows(B5): 1 ematen du, gelaxka batek errenkada bakarra baitu.

=ROWS(A10:B12): 3 ematen du.

=ROWS(Untxia): 3 ematen du, "Untxia" bada barruti izenduna (C1:D3).

## SHEET

Erreferentzia baten edo orri-izen bat adierazten duen kate baten orri-zenbakia ematen du. Ez baduzu parametrorik sartzen, formula duen kalkulu-orriaren orri-zenbakia izango da emaitza.

### Sintaxia

SHEET(Erreferentzia)

Erreferentzia: gelaxka baten, barruti baten edo orri-izen baten karaktere-katearen erreferentzia. Aukerakoa da.

### Adibidea

=SHEET(Orria2.A1): 2 ematen du, Orria2 kalkulu-orriko bigarren orria bada.

## SHEETS

Erreferentzia bateko orri kopurua zehazten du. Ez baduzu parametrorik sartzen, uneko dokumentuko orri kopurua emango du.

### Sintaxia

SHEETS(erreferentzia)

Erreferentzia: orri edo barruti baten erreferentzia da. Parametro hau aukerakoa da.

### Adibidea

=SHEETS(Orria1.A1:Orria3.G12): 3 ematen du, Orria1, Orria2 eta Orria3 badaude adierazitako sekuentzian.

## STYLE

Estilo bat aplikatzen dio formularen gelaxkari. Ezarritako denbora igaro ondoren, beste estilo bat aplika daiteke. Funtzio honek beti 0 balioa ematen du, eta balioa aldatu gabe beste funtzio bati gehi dakioke. CURRENT funtzioarekin batera kolore bat aplika diezaiokezu gelaxkari, balioaren arabera. Adibidez: Balioa 3 baino handiagoa bada, =...+STYLE(IF(CURRENT()>;3;"gorria";"berdea")) funtzioak "gorria" estiloa aplikatzen dio gelaxkari; bestela, "berdea" estiloa. Bi gelaxka-formatuak, "gorria" eta "berdea", aurretiaz definitu behar dira.

### Sintaxia

STYLE(estiloa;denbora;estiloa)

Estiloa: gelaxkari aplikatu beharreko estiloaren izena. Estilo-izenak komatxoen artean sartu behar dira.

Denbora: aukerako denbora-tartea (segundotan). Parametro hau falta bada, estiloa ez da aldatuko denbora-tarte jakin bat igarotakoan.

Estiloa2: denbora-tarte jakin bat igaro ondoren gelaxkari esleitutako estiloaren aukerako izena. Parametro hau falta bada, "Estandarra" sartzen da.

LibreOffice Calc-eko funtzioetan, "aukerakoa" marka daukaten parametroak alde batera utz daitezke ondoren parametrorik ez dagoenean soilik. Adibidez, lau parametro dituen funtzio batean, funtzio horietako azken biek "aukerakoa" marka badaukate, 4. parametroa edo 3. eta 4. parametroa alde batera utz ditzakezu, baina ezin duzu alde batera utzi 3. parametroa bakarrik.

### Adibidea

=STYLE("Invisible";60;"Default"): gelaxkari formatu gardena emango dio dokumentua birkalkulatu edo kargatu eta 60 segundo igarotakoan; ondoren formatu Lehenetsia esleituko zaio. Bi gelaxka-formatuak aurretiaz definitu behar dira.

STYLE() funtzioak zenbakizko itzulera-balio bat daukanez, itzulera-balio hori karaktere-kate bati eransten zaio. T() erabiliz saihestu daiteke hori, hurrengo adibidean bezala:

="Text"&T(STYLE("myStyle"))

Ikus halaber CURRENT(), beste adibide bat ikusteko.

## VLOOKUP

Bilaketa bertikala eskuineko ondoz ondoko gelaxken erreferentziarekin. Balio jakin bat matrizearen lehen zutabean badagoen begiratzen du funtzio honek. Orduan funtzioak balioa itzultzen du indizeak izendatutako zutabeko errenkada berean. Ordenatua parametroa ez bada zehazten edo TRUE (egiazkoa) ezartzen bada, datuak goranzko ordenan ordenatu behar direla ulertzen da. Kasu horretan, bilaketa-irizpidea ez bada aurkitzen, hurrengo balioa itzuliko da. Ordenatua FALSE (faltsua) edo zero bada, zehatz-mehatz bat datorrena aurkitu behar da, eta bestela errore hau emango du: Errorea: balioa ez dago eskuragarri. Hortaz, zero balioarekin ez dago datuak gorantz ordenatu beharrik.

Bilaketak adierazpen erregularrak onartzen ditu. Esaterako, "dena.* sartu dezakezu, "dena" hitza edozein karaktere kopururekin jarraituta aurkitu nahi baduzu. Adierazpen erregularra ere baden testuren bat bilatu nahi baduzu, karaktere bakoitzari "\" karaktere bat idatzi behar diozu aurrean. Adierazpen erregularren ebaluazio automatikoa aktibatu eta desaktibatu dezakezu LibreOffice - Hobespenak Tresnak - Aukerak - LibreOffice Calc - Kalkulatu atalean.

### Sintaxia

=VLOOKUP(Bilaketa-irizpidea;matrizea;indizea;ordenatuta)

Bilaketa-irizpidea: matrizearen lehen zutabean bilatu beharreko balioa.

Matrizea erreferentzia da, Indize argumentuan pasatu den zenbakiak bezain besteko zutabe gutxienez hartzen dituena.

Indizea: bilatzen ari den balioa duen matrizeko zutabearen zenbakia. Lehen zutabearen zenbakia 1 da.

Ordenatuta: aukerako parametroa da, eta matrizeko lehen zutabea gorantz ordenatuta dagoen zehazten du. Lehen zutabea goranzko ordenan ordenatuta ez badago, sartu FALSE (faltsua) balio logikoa edo zero. Ordenatutako zutabeak askoz ere azkarrago bilatzen dira eta funtzioak beti ematen du balio bat, baita bilaketa balioarekin zehazki bat datorren baliorik ez badago ere (zerrenda ordenatuaren balio txikien eta handienaren artean baldin badago). Ordenatu gabeko zerrendetan balioak guztiz bat etorri beharko du. Bestela funtzioak mezu hau bistaratuko du: Errorea: balioa ez dago erabilgarri.

Gelaxka hutsen kudeaketa

### Adibidea

Demagun menuko plater baten zenbakia sartu nahi duzula A1 gelaxkan, eta plateraren izena testu gisa bistaratu nahi duzula ondoko gelaxkan (B1). Kode eta izenaren arteko korrespondentzia D1:E100 matrizean esleitzen da. D1 gelaxkak 100 balioa dauka, E1 gelaxkak Arrain-zopa plater-izena, eta abar. 100 plater daude guztira. D zutabeko zenbakiak goranzko ordenan daude; hortaz, Ordenatua aukerako parametroa ez da beharrezkoa.

Sartu formula hau B1 gelaxkan:

=VLOOKUP(A1;D1:E100;2)

A1 gelaxkan zenbaki bat sartzen duzun bezain laster, D1:E100 erreferentziaren bigarren zutabeko testua erakutsiko du B1 gelaxkak. Lehendik ez dagoen zenbaki bat sartzen baduzu, (behera) hurrengo zenbakia duen testua bistaratuko du. Hori gerta ez dadin, formulan sartu FALSE (faltsua) azken parametro gisa, eta horrela errore-mezua emango du lehendik ez dagoen zenbakia sartutakoan.

Erlazionatutako gaiak

Funtzioak kategoriaren arabera