Edukiak
Indizea 🔎︎

# MINIFS funtzioa

Barruti anitzetan irizpide anitz betetzen dituzten gelaxketako balioen minimoa ematen du.

Funtzio hau LibreOffice bertsiotik existitzen da5.2

### Sintaxia

MINIFS(FuntzioBarrutia; Barrutia1; Irizpidea1 [ ; Barrutia2; Irizpidea2 [;...]]))

FuntzioBarrutia – derrigorrezko argumentua. Gelaxka-barruti bat, izendatutako barruti baten izen bat, edo zutabe edo errenkada baten etiketa bat da, minimoa kalkulatzeko erabiliko diren balioak dituena.

Irizpidea1 – derrigorrezko argumentua. Kate motako adierazpen bat, baldintza logiko bat edo kate-adierazpen horren gelaxka-erreferentzia bat ordezkatzen duena. Adierazpenak testua, zenbakiak, adierazpen erregularrak edo komodinak izan ditzake (kalkuluaren aukeretan gaituta badaude).

Barrutia2 – Aukerakoa. Barrutia2 eta hurrengoek Barrutia1 parametroaren esanahi bera dute.

Irizpidea2 – Aukerakoa. Irizpidea2 eta hurrengoek Irizpidea1 parametroaren esanahi bera dute.

FuntzioBarrutia eta Barrutia1,Barrutia2... parametroek tamaina bera izan behar dute, bestela funtzioak 'err:502 - Baliogabeko argumentua' errorea itzuliko du.

Irizpideen arteko erlazio logikoa AND logiko modura definitu daiteke. Alegia, emandako irizpide guztiak betetzen badira (eta soilik horrela bada), hartuko da kontuan kalkuluan emandako FuntzioBarrutia parametroari dagokion balio bat.

Funtzioak 255 argumentu arte izan ditzake; alegia, 127 irizpide-barruti eta irizpide zehaztu daitezke funtziorako.

Gelaxka batek TRUE (Egiazkoa) badu, 1 baliotzat hartzen du; FALSE (Gezurra) badu, 0 (zero) baliotzat.

Funtzio hori Open Document Format for Office Applications (OpenDocument) estandarraren 1.2 bertsioan (ISO/IEC 26300:2-2015) dago onartuta.

### Adibidea

#### Begiratu honako taula

| A | B | C
1 | Produktuaren izena | Salmentak | Diru-sarrerak
2 | arkatza | 20 | 65
3 | luma | 35 | 85
4 | koadernoa | 20 | 190
5 | liburua | 17 | 180
6 | arkatz-kutxa | ez | ez

Beheko adibide guztietan batuketa kalkulatzeko barrutiek #6 errenkada dute, baina hura ez ikusi egingo da testua duelako.

#### Erabilera sinplea

=MINIFS(B2:B6;B2:B6;"<35")

B2:B6 barrutiko balioen minimoa kalkulatzen du, 20 balioaren berdina edo txikiagoa bada. 17 ematen du.

=MINIFS(C2:C6;B2:B6;">=20";C2:C6;">90")

C2:C6 barrutian 90 baino txikiagoak diren eta B2:B6 barrutian 20 balioaren berdina edo handiagoak diren balioak dituzten gelaxkei dagozkien balioen minimoa kalkulatzen du. 190 ematen du.

#### Adierazpen erregularrak eta habiaratutako funtzioak erabiltzea

=MINIFS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

C2:C6 barrutian B2:B6 barrutiko balio guztiei dagozkien balioen minimoa kalkulatzen du, minimoa eta maximoa salbu. 65 ematen du.

=MINIFS(C2:C6;A2:A6;".*liburu";B2:B6;"<="&MAX(B2:B6))

C2:C6 barrutiko balioen batuketa kalkulatzen du, "pen" katearekin hasten diren A2:A6 barrutiko gelaxkekin eta B2:B6 barrutiko gelaxka guztiekin (minimoa salbu) bat datozen balioak soilik hartuta. 180 ematen du.

#### Irizpidetzat gelaxka baten erreferentzia erabiltzea

Irizpide bat erraz aldatu behar baduzu, beste gelaxka batean zehaztu dezakezu eta gelaxka horren erreferentzia bat erabili MINIFS funtzioaren baldintzan. Adibidez, goiko funtzioa beste modu honetan idatzi daiteke:

=MINIFS(C2:C6;A2:A6;".*"&E2;B2:B6;"<"&MAX(B2:B6))

E2 = "liburu" bada, funtzioak 180 ematen du, gelaxkarako erreferentzia bere edukiarekin ordezkatuko delako.

Erlazionatutako gaiak

MAX, MAXA, MIN, MINA,

COUNTIFS, MINIFS, MAXIFS, AVERAGEIFS, SUMIFS

Adierazpen erregularren zerrenda