Conteúdo
Índice 🔎︎

# função MÁXIMO.SE.S

Devolve o máximo dos valores das células de um intervalo que cumpra critérios múltiplos em vários intervalos.

Esta função está disponível desde o LibreOffice 5.2

### Sintaxe

MÁXIMO.SE.S(intervalo_func; intervalo1; critério1 [ ; intervalo2; critério2 [;...]]))

intervalo_func – argumento obrigatório. Um intervalo, um nome de intervalo ou um rótulo de coluna ou linha contendo os valores para calcular o máximo.

critério1 – obrigatório. Uma expressão de texto representando uma condição lógica, ou uma referência de contendo uma expressão de texto. A expressão pode conter texto, números, expressões regulares ou caracteres universais (se estas estiverem ativadas nas opções de cálculo).

intervalo2 – Opcional. intervalo2 e todos os seguintes têm o mesmo significado que intervalo1.

critério2 – Opcional. critério2 e todos os seguintes têm mesmo significado que critério1.

Intervalo_Func e intervalo1, intervalo2... devem ter o mesmo tamanho, senão a função devolve err:502 - argumento inválido.

A relação lógica entre os critérios pode ser definida como E lógico (conjunção). Em outras palavras, se e apenas se todos os critérios são verificados, um valor da célula correspondente ao intervalo intervalo_func é computada.

A função pode ter até 255 argumentos, significando que pode haver 127 intervalos de critérios e critérios correspondentes.

Se a célula contiver VERDADEIRO, será tratada como 1 e se contiver FALSO, será tratada como 0 (zero).

Esta função é parte integrante da norma Open Document Format for Office Applications (OpenDocument), versão 1.2 (ISO/IEC 26300:2-2015).

### Exemplo

#### Considere a seguinte tabela

| A | B | C
1 | Nome do produto | Vendas | Rendimento
2 | pencil | 20 | 65
3 | pen | 35 | 85
4 | caderno | 20 | 190
5 | book | 17 | 180
6 | pencil-case | não | não

Em todos os exemplos abaixo, os intervalo de cálculo contêm a linha n.º 6, que é ignorada por que contém texto.

#### Utilização

=MÁXIMO.SE.S(B2:B6;B2:B6;"<35")

Calcula o máximo dos valores do intervalo B2:B6 que são maiores ou iguais a 20. Devolve 35, uma vez que a 5.ª linha não cumpre o critério.

=MÁXIMO.SE.S(C2:C6;B2:B6;">=20";C2:C6;"<90")

Calcula o máximo dos valores no intervalo C2:C6 menores que 90 e correspondentes às células do intervalo B2:B6 com valores maiores de 20. Devolve 85, por que a 4.ª e 5.ª linhas não cumprem pelo menos um critério.

#### Utilizar expressões regulares e funções incorporadas

=MÁXIMO.SE.S(C2:C6;B2:B6;">"&MÍNIMO(B2:B6);B2:B6;"<"&MÁXIMO(B2:B6))

Calcula o máximo dos valores do intervalo C2:C6 que correspondem a todos os valores do intervalo B2:B6, exceto o seu máximo e o seu mínimo. Devolve 190, por que apenas a 4.ª linha cumpre os critérios.

=MÁXIMO.SE.S(C2:C6;A2:A6;"pen.*";B2:B6;"<="&MÁXIMO(B2:B6))

Calcula o máximo dos valores do intervalo C2:C6 que corresponde a todas as células do intervalo A2:A6 iniciando com "pen", e de todas as células do intervalo B2:B6, exceto o seu máximo. Devolve 85 por que apenas a 3.ª linha cumpre o critério.

#### Referência a uma célula como critério

Se precisar mudar o critério facilmente, você pode especificá-lo numa célula em separado e utilizar a referência a esta célula na condição da função MÁXIMO.SE.S. Por exemplo, a função acima pode ser reescrita como segue:

=MÁXIMO.SE.S(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MÁXIMO(B2:B6))

Se E2="pen", a função devolve 65, porque a referência à célula é substituída pelo seu conteúdo.

Tópicos relacionados

MÁXIMO, MÁXIMOA, MÍNIMO, MÍNIMOA,

CONTAR.SE.S, Função MÍNIMO.SE.S, função MÁXIMO.SE.S, MÉDIA.SE.S, Função SOMA.SE.S

Lista de expressões regulares