Contenu
Index 🔎︎

# Fonctions mathématiques

Cette catégorie contient les fonctions mathématiques de Calc. Pour ouvrir l'assistant Fonctions, choisissez Insertion - Fonction.

## AGREGAT

Cette fonction renvoie un résultat groupé des calculs de la plage. Vous pouvez utiliser différentes fonctions de groupement listées ci-dessous. La fonction AGREGAT vous permet d'omettre les lignes masquées, les erreurs, SOUS-TOTAUX et les autres résultats de fonction AGREGAT du calcul.

## SOUSTRAIRE.BRUT

Soustrait un ensemble de nombres et donne le résultat sans éliminer les petites erreurs d'arrondis.

### COULEUR

Renvoie une valeur numérique calculée par une combinaisons de trois couleurs (rouge, vert et bleu) et le canal alpha dans le système de couleur RVBA.Le résultat dépend du système de couleurs utilisé par votre ordinateur.

## SOMME.SI.ENS

Renvoie la somme des valeurs des cellules d'une plage qui répond à des critères multiples dans plusieurs plages.

## SOMME.SERIES

Additionne les premiers termes d'une série de puissances

SOMME.SERIES(x;n;m;coefficients) = coefficient_1*x^n + coefficient_2*x^(n+m) + coefficient_3*x^(n+2m) +...+ coefficient_i*x^(n+(i-1)m)

#### Syntaxe

SOMME.SERIES(x;n;m;coefficients)

x est la valeur de saisie de la série de puissances.

n est la puissance initiale

m est l'incrément pour augmenter n

coefficients est une série de coefficients. Pour chaque coefficient, la somme des séries est étendue d'une section.

## SOMME

Additionne tous les nombres d'une plage de cellules.

#### Syntaxe

SOMME(nombre_1;nombre_2;...;nombre_30)

Nombre1 à Nombre30 représentent jusqu'à 30 arguments, aussi bien des cellules que des plages, dont la somme doit être calculée.

SOMME ignore tout texte ou cellules vides dans une plage ou une matrice. Si vous suspectez un résultat faux de la fonction SOMME, recherchez du texte dans les plages de données. Utilisez la fonction Mise en évidence des valeurs pour mettre en surbrillance les contenus texte dans la plage qui peuvent représenter un nombre.

#### Exemple

Si vous saisissez les nombres 2 ; 3 et 4 dans la zone de texte nombre 1 ; 2 et 3, 9 sera le résultat renvoyé.

=SOMME(A1;A3;B5) calcule la somme des trois cellules. =SOMME(A1:E10) calcule la somme de toutes les cellules de la plage A1 à E10.

Avec la fonction SOMME(), vous pouvez utiliser des conditions reliées par ET de la manière suivante :

Par exemple : vous avez saisi des factures dans une table. La colonne A contient la valeur de date de la facture, la colonne B contient le montant. Vous souhaitez trouver une formule que vous pourrez utiliser pour renvoyer le total des montants uniquement pour un mois spécifique, p.e. seul le montant pour la période >=01-01-2008 au <01-02-2008. La plage des valeurs de date est A1:A40, la plage contenant les montants devant être totalisés est B1:B40. C1 contient la date de départ, 01-01-2008, des factures qui doivent être incluses et C2 la date, 01-02-2008, qui n'est plus incluse.

Saisissez la formule de matrice suivante :

=SOMME((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

Pour que la formule soit bien interprétée comme une formule de matrice, vous devez la saisir en appuyant sur les touches Maj+Commande+Ctrl+Entrée, et non simplement en appuyant sur la touche Entrée. La formule s'affiche alors entre accolades dans la barre de formule.

{=SOMME((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

La formule est basée sur le fait que le résultat d'une comparaison est 1 si le critère est rencontré et 0 s'il ne l'est pas. Les résultats de la comparaison individuelle seront traités comme une matrice et utilisés dans la multiplication matricielle et, à la fin, les valeurs individuelles seront totalisées pour donner la matrice de résultat.

## SOMME.SI

Ajoute les cellules spécifiées par un critère donné. Vous pouvez utiliser cette fonction pour rechercher une valeur donnée dans une plage.

La recherche prend en charge les caractères génériques ou les expressions régulières . Lorsque les expressions régulières sont activées, vous pouvez saisir "tous. *", Par exemple pour trouver le premier emplacement de "tous" suivi de n'importe quel caractère. Si vous souhaitez rechercher un texte qui est également une expression régulière, vous devez soit précéder chaque caractère d'un caractère "\", soit placer le texte dans \Q ...\E. Vous pouvez activer ou désactiver l'évaluation automatique des caractères génériques ou des expressions régulières dans LibreOffice - Préférences Outils - Options - LibreOffice Calc - Calculer .

Lorsque vous utilisez des fonctions où un ou plusieurs arguments sont des chaînes de critères de recherche qui représentent une expression régulière, la première tentative consiste à convertir les critères de chaîne en nombres. Par exemple, ".0" se convertira en 0.0 et ainsi de suite. En cas de succès, la correspondance ne sera pas une correspondance d'expression régulière mais une correspondance numérique. Cependant, lorsque vous passez à un environnement local où le séparateur décimal n'est pas le point, la conversion d'expression régulière fonctionne. Pour forcer l'évaluation de l'expression régulière au lieu d'une expression numérique, utilisez une expression qui ne peut pas être mal interprétée comme numérique, telle que ". [0]" ou ".\0" ou "(?I) .0".

#### Syntaxe

SOMME.SI(plage;critère;plage_de_somme)

plage est la plage de cellules à laquelle les critères doivent être appliqués.

critère correspond à la cellule dans laquelle s'affiche le critère de recherche, ou au critère lui-même. Si le critère est écrit dans la formule, il doit être délimité par des guillemets.

plage_de_somme est la plage à partir de laquelle les valeurs sont additionnées. Si ce paramètre n'a pas été indiqué, les valeurs trouvées dans la plage sont additionnées.

SOMME.SI prend en charge l'opérateur de concaténation de référence (~) seulement dans le paramètre critère et seulement si le paramètre facultatif plage_de_somme n'est pas donné.

#### Exemple

Pour additionner uniquement des valeurs négatives : =SOMME.SI(A1:A10;"<0")

=SOMME.SI(A1:A10;">0";B1:B10) - additionne les valeurs de la plage B1:B10 uniquement si les valeurs correspondantes dans la plage A1:A10 sont >0.

Pour des exemples de syntaxe supplémentaires utilisables avec SOMME.SI(), voir NB.SI().

## ISO.PLAFOND

Arrondi un nombre au multiple significatif supérieur, peu importe le signe de la précision

#### Syntaxe

ISO.PLAFOND(nombre;précision)

nombre (requis) est le nombre à arrondir.

précision (facultatif) est le nombre pour le multiple duquel la valeur doit être arrondie.

#### Exemple

=ISO.PLAFOND(-11;-2)renvoie -10

## PLAFOND.PRECIS

Arrondi un nombre au multiple significatif supérieur, peut importe le signe de la précision.

Cette fonction est disponible depuis LibreOffice 4.3

#### Syntaxe

PLAFOND.PRECIS(nombre;précision)

nombre (requis) est le nombre à arrondir.

précision (facultatif) est le nombre supérieur pour le multiple duquel la valeur doit être arrondie.

#### Exemple

=PLAFOND.PRECIS(-11;-2) renvoie -10

## PLANCHER.PRECIS

Arrondit un nombre au multiple significatif inférieur le plus proche, peu importe le signe de la précision

Cette fonction est disponible depuis LibreOffice 4.3

#### Syntaxe

PLAFOND.PRECIS(nombre;précision)

nombre est le nombre devant être arrondi.

précision est la valeur vers le multiple de laquelle le nombre est arrondi.

Si le classeur est exporté dans Microsoft Excel, la fonction PLANCHER est exportée comme équivalente à la fonction PLANCHER.MATH qui existe depuis Excel 2013. Si vous envisagez d'utiliser le classeur avec des versions antérieures d'Excel, utilisez la fonction PLANCHER.PRECIS qui existe depuis Excel 2010 ou PLANCHER.XCL qui est exportée comme la fonction PLANCHER compatible avec toutes les versions Excel. Remarquez que PLANCHER.XCL arrondit toujours les nombres autour de zéro.

#### Exemple

=PLANCHER.PRECIS(-11;-2) renvoie -12

## PLANCHER

Arrondit un nombre au multiple significatif inférieur le plus proche.

#### Syntaxe

PLANCHER(nombre;précision;mode)

nombre est le nombre devant être arrondi.

précision est la valeur vers le multiple de laquelle le nombre est arrondi.

mode est une valeur facultative. Si la valeur de mode est donnée et différente de zéro, et si Nombre et Précision sont négatifs, alors l'arrondi est fait en se basant sur la valeur absolue de Nombre, i.e les nombres négatifs sont arrondis autour de zéro. Si la valeur Mode est égale à zéro ou omise, les nombres négatifs sont arrondis en s'éloignant de zéro.

Si le classeur est exporté dans Microsoft Excel, la fonction PLANCHER est exportée comme équivalente à la fonction PLANCHER.MATH qui existe depuis Excel 2013. Si vous envisagez d'utiliser le classeur avec des versions antérieures d'Excel, utilisez la fonction PLANCHER.PRECIS qui existe depuis Excel 2010 ou PLANCHER.XCL qui est exportée comme la fonction PLANCHER compatible avec toutes les versions Excel. Remarquez que PLANCHER.XCL arrondit toujours les nombres autour de zéro.

#### Exemple

=PLANCHER(-11;-2) renvoie -12

=PLANCHER(-11;-2;0) renvoie -12

=PLANCHER(-11;-2;1) renvoie -10

## PLAFOND

Arrondit un nombre au multiple significatif supérieur le plus proche.

#### Syntaxe

PLAFOND(nombre;précision;mode)

nombre correspond au nombre à arrondir.

précision est le nombre supérieur pour le multiple duquel la valeur doit être arrondie.

Mode est une valeur facultative. Si la valeur mode est donnée et n'est pas égle à zéro, et si Nombre et Précision sont négatifs, alors l'arrondi est fait basé sur la valeur absolue de Nombre, i.e. les nombres négatifs sont arrondis en s'éloignant de zéro. Si la valeur mode est égale à zéro ou est omise, les nombres négatifs sont arrondis autour de zéro.

Si le classeur est exporté dans Microsoft Excel, la fonction PLAFOND est exportée comme équivalente à la fonction PLAFOND.MATH qui existe depuis Excel 2013. Si vous envisagez d'utiliser le classeur avec des versions antérieures d'Excel, utilisez soit PLAFOND.PRECIS qui existe depuis Excel 2010, ou PLAFOND.XCL qui est exporté comme la fonction PLAFOND compatible avec toutes les versions Excel. Remarquez que PLAFOND.XCL arrondit toujours les nombres en s'éloignant de zéro.

#### Exemple

=PLAFOND(-11;-2) renvoie -10

=PLAFOND(-11;-2;0) renvoie -10

=PLAFOND(-11;-2;1) renvoie -12

## PLAFOND.MATH

Arrondit un nombre au multiple significatif supérieur le plus proche.

#### Syntaxe

PLAFOND.MATH(nombre;précision;mode)

nombre correspond au nombre à arrondir.

précision est le nombre supérieur pour le multiple duquel la valeur doit être arrondie.

Mode est une valeur facultative. Si la valeur mode est donnée et n'est pas égale à zéro, et si Nombre et Précision sont négatifs, alors l'arrondi est fait basé sur la valeur absolue de Nombre, i.e. les nombres négatifs sont arrondis en s'éloignant de zéro. Si la valeur mode est égale à zéro ou est omise, les nombres négatifs sont arrondis autour de zéro.

Cette fonction existe pour des raisons d'interopérabilité avec Microsoft Excel 2013 ou supérieure.

#### Exemple

=PLAFOND.MATH(-10;-3) renvoie -9

=PLAFOND.MATH(-10;-3;0) renvoie -9

=PLAFOND.MATH(-10;-3;1) renvoie -12

## ARRONDI.INF

Arrondit un nombre en tendant vers zéro, jusqu'à une certaine précision.

#### Syntaxe

ARRONDI.INF(nombre;nombre)

Renvoie le nombre à l'arrondi inférieur (tendant vers zéro) du nombre de décimales. Si le nombre est omis ou est zéro, la fonction arrondit à l'inférieur d'un nombre entier. Si le nombre est négatif, la fonction arrondit à l'inférieur au plus proche de 10, 100, 1000, etc.

Cette fonction arrondit autour de zéro. Voir ARRONDI.SUP et ARRONDI pour des alternatives.

#### Exemple

=ARRONDI.INF(1,234;2) renvoie 1,23.

=ARRONDI.INF(45,67;0) renvoie 45.

=ARRONDI.INF(-45,67) renvoie -45.

=ARRONDI.INF(987,65;-2) renvoie 900.

## IMPAIR

Arrondit un nombre positif au nombre entier impair supérieur le plus proche, et un nombre négatif au nombre entier impair inférieur le plus proche.

#### Syntaxe

IMPAIR(nombre)

Renvoie le nombre arrondi au plus proche nombre entier impair supérieur, éloigné de zéro.

#### Exemple

=IMPAIR(1,2) renvoie 3.

=IMPAIR(1) renvoie 1.

=IMPAIR(0) renvoie 1.

=IMPAIR(-3,1) renvoie -5.

## PAIR

Arrondit un nombre positif au nombre entier pair supérieur le plus proche et un nombre négatif au nombre entier pair inférieur le plus proche.

#### Syntaxe

PAIR(nombre)

Renvoie le nombre arrondi au plus proche nombre entier pair supérieur, éloigné de zéro.

#### Exemple

=PAIR(2,3) renvoie 4.

=PAIR(2) renvoie 2.

=PAIR(0) renvoie 0.

=PAIR(-0,5) renvoie -2.

## ENT

Arrondit un nombre à l'entier immédiatement inférieur.

#### Syntaxe

ENT(nombre)

Renvoie nombre à l'arrondi inférieur le plus proche du nombre entier.

Nombres négatifs arrondis au nombre entier inférieur.

#### Exemple

=ENT(5,7) renvoie 5.

=ENT(-1,3) renvoie -2.

## ARRONDI

Arrondit un nombre à un nombre spécifique de décimales.

#### Syntaxe

ARRONDI(nombre;nombre)

Renvoie le nombre arrondi au nombre de décimales. Si le nombre est omis ou est zéro, la fonction arrondit au nombre entier le plus proche. Si le nombre est négatif, la fonction arrondit au plus proche de 10, 100, 1000, etc.

Cette fonction arrondit au nombre le plus proche. Voir ARRONDI.INF et ARRONDI.SUP pour des alternatives.

#### Exemple

=ARRONDI(2,348;2) renvoie 2,35

=ARRONDI(-32,4834;3) renvoie -32,483. Modifiez le format de la cellule pour afficher toutes les décimales.

=ARRONDI(2,348;0) renvoie 2.

=ARRONDI(2,5) renvoie 3.

=ARRONDI(987,65;-2) renvoie 1 000.

## ARRONDI.SUP

Arrondit un nombre à la valeur immédiatement supérieure en fonction de la décimale spécifiée.

#### Syntaxe

ARRONDI.SUP(nombre;nombre)

Renvoie le nombre arrondi à la valeur supérieure (éloignée de zéro) au nombre de décimales. Si le nombre est omis ou est zéro, la fonction arrondit au nombre entier supérieur. Si le nombre est négatif, la fonction arrondit au supérieur au plus proche de 10, 100, 1 000, etc.

Cette fonction arrondit en s'éloignant de zéro. Voir ARRONDI.INF et ARRONDI pour des alternatives.

#### Exemple

=ARRONDI.SUP(1,1111;2) renvoie 1,12.

=ARRONDI.SUP(1,2345;1) renvoie 1,3.

=ARRONDI.SUP(45,67;0) renvoie 46.

=ARRONDI.SUP(-45,67) renvoie -46.

=ARRONDI.SUP(987,65;-2) renvoie 1 000.

## PLAFOND.XCL

Arrondit un nombre éloigné de zéro au multiple significatif supérieur le plus proche.

Cette fonction est disponible depuis LibreOffice 5.0

#### Syntaxe

PLAFOND.XCL(nombre;précision)

nombre est le nombre devant être arrondi.

précision est la nombre vers le multiple duquel la valeur est arrondie.

Cette fonction existe pour des raisons d'interopérabilité avec Microsoft Excel 2007 et versions inférieures.

#### Exemple

=PLAFOND.XCL(1;3) renvoie 3

=PLAFOND.XCL(7;4) renvoie 8

=PLAFOND.XCL(-10;-3) renvoie -12

## SOUS.TOTAL

Calcule les sous-totaux. Si une plage donnée contient déjà des sous-totaux, ceux-ci ne sont pas utilisés pour des calculs ultérieurs. Pour que le calcul ne porte que sur les enregistrements filtrés, associez cette fonction aux AutoFiltres.

#### Syntaxe

SOUS.TOTAL(fonction;plage)

fonction est un nombre qui représente l'une des fonctions suivantes :

Index des fonctions (inclut les valeurs masquées) | Index des fonctions (ignore les valeurs masquées) | Fonctions
1 | 101 | MOYENNE
2 | 102 | NB
3 | 103 | NBVAL
4 | 104 | MAX
5 | 105 | MIN
6 | 106 | PRODUIT
7 | 107 | ECARTYPE
8 | 108 | ECARTYPEP
9 | 109 | SUM
10 | 110 | VAR
11 | 111 | VARP

Utilisez les nombres 1-11 pour inclure manuellement les lignes masquées ou 101-111 pour les exclure ; les cellules filtrées sont toujours exclues.

plage correspond à la plage dont les cellules sont incluses.

#### Exemple

Il y a un tableau dans la plage de cellule A1:B6 contenant une facture de matériel pour 10 élèves. La ligne 2 (stylos) est masquée manuellement. Vous voulez voir la somme des nombres qui sont affichés ; c'est-à-dire le sous-total des lignes filtrées. Dans ce cas, la formule correcte est :

| A | B
1 | ÉLÉMENT | QUANTITÉ
2 | Stylo | 10
3 | Crayon | 10
4 | Bloc-notes | 10
5 | Gomme | 10
6 | Taille-crayons | 10

=SOUS.TOTAL(9;B2:B6) renvoie 50.

=SOUS.TOTAL(109;B2:B6) renvoie 40.

## EUROCONVERT

Cette fonction convertit en euros les anciennes monnaies nationales européennes et de Euros en Euros.

#### Syntaxe

EUROCONVERT(Valeur;"de_monnaie";"en_monnaie",précision_complète,précision_triangulation)

valeur est le montant de la monnaie à convertir.

de_monnaie et en_monnaie sont les unités monétaires à convertir de et en respectivement. Cela doit être du texte, l'abréviation officielle de la monnaie (par exemple "EUR"). Le taux de conversion (affiché en euro) a été fixé par la Commission Européenne.

Précision_complète est facultatif. Si omis ou faux, le résultat est arrondi en fonction des décimales de En monnaie. Si Précision_complète est vrai, le résultat n'est pas arrondi.

Précision_triangulation est facultatif. Si Précision_triangulation est donné et >=3, le résultat intermédiaire d'une conversion triangulaire (monnaie1,EUR,monnaie2) est arrondi à cette précision. Si Précision_triangulation est omis, le résultat intermédiaire n'est pas arrondi. De même, si la monnaie est "EUR", Précision_triangulation est utilisé comme si la triangulation était nécessaire et la conversion de EUR en EUR était appliquée.

### Exemples

=EUROCONVERT(100;"ATS";"EUR") convertit 100 shillings autrichiens en euros.

=EUROCONVERT(100;"EUR";"DEM") convertit 100 euros en marks allemands.

## RADIANS

Convertit les degrés en radians.

#### Syntaxe

RADIANS(nombre)

nombre est l'angle en degrés à convertir en radians.

#### Exemple

=RADIANS(90) renvoie 1,5707963267949, qui est PI/2 à la précision de Calc.

## DEGRES

Convertit les radians en degrés.

#### Syntaxe

DEGRES(nombre)

nombre est l'angle en radians à convertir en degrés.

#### Exemple

=DEGRES(PI()) renvoie 180 degrés.

## CONVERTIR_OOO

Convertit une valeur d'une unité de mesure en une autre unité de mesure. Les facteurs de conversion sont donnés dans une liste dans la configuration.

À un moment, la liste de facteurs de conversion incluait les monnaies anciennes européennes et l'Euro (voir les exemples ci-dessous). Nous vous suggérons d'utiliser la nouvelle fonction EUROCONVERT pour convertir ces monnaies.

#### Syntaxe

CONVERTIR_OOO(valeur;"texte";"texte")

#### Exemple

=CONVERTIR_OOO(100;"ATS";"EUR") renvoie la valeur en Euro de 100 shillings autrichiens.

=CONVERTIR_OOO(100;"EUR";"DEM") convertit 100 Euros en marks allemands.

## PRODUIT

Donne le produit de la multiplication de tous les nombres donnés comme arguments.

#### Syntaxe

PRODUIT(nombre_1;nombre_2;...;nombre_30)

nombre1 à 30 représente jusqu'à 30 arguments dont le produit doit être calculé.

PRODUIT renvoie nombre1 * nombre2 * nombre3 * ...

#### Exemple

=PRODUIT(2;3;4) renvoie 24.

## PPCM_EXCEL2003

Le résultat est le plus petit multiple commun d'une liste de nombres.

Les fonctions dont les noms se terminent par _ADD ou _EXCEL2003 renvoient le même résultat que les fonctions correspondantes Microsoft Excel 2003 sans le suffixe. Utilisez les fonctions sans suffixe pour obtenir des résultats basés sur les standards internationaux.

#### Syntaxe

PPCM_EXCEL2003(nombres(s))

nombre(s) est une liste contenant jusqu'à 30 nombres.

#### Exemple

=PPCM_EXCEL2003(5;15;25) revoie 75.

## ARRONDI.AU.MULTIPLE

Le résultat obtenu est le multiple entier le plus proche du nombre.

#### Syntaxe

ARRONDI.AU.MULTIPLE(nombre;multiple)

Renvoie un nombre arrondit au multiple le plus proche de multiple.

Une implémentation alternative serait Multiple * ARRONDI(nombre/multiple).

#### Exemple

=ARRONDI.AU.MULTIPLE(15,5;3) renvoie 15, car 15,5 est plus près de 15 (= 3*5) que de 18 (= 3*6).

=ARRONDI.AU.MULTIPLE(1,4;0,5) renvoie 1,5 (= 0,5*3).

## PI

Renvoie 3,14159265358979, la valeur de la constante mathématique PI à 14 décimales.

#### Syntaxe

PI ()

#### Exemple

=PI() renvoie 3,14159265358979.

## EXP

Renvoie e élevé à la puissance d'un nombre. La constante e a une valeur approximative de 2,71828182845904.

#### Syntaxe

EXP(nombre)

nombre est la puissance à laquelle e doit être élevé.

#### Exemple

=EXP(1) renvoie 2,71828182845904, la constante mathématique e à la précision de Calc.

## ATAN2

Renvoie l'angle (en radians) entre l'axe x et une ligne de l'origine au point (NombreX|NombreY).

Cette fonction fait partie du standard Open Document Format for Office Applications (Open Document) Version 1.2 (ISO/IEC 26300:2-2015)

#### Syntaxe

ATAN2(nombreX;nombreY)

nombreX est la valeur de la coordonnée x.

nombreY représente la valeur des coordonnées y.

Les langages de programmation ont habituellement l'ordre opposé des arguments pour leur fonction atan2().

ATAN2 renvoie l'angle (en radians) entre l'axe x et une ligne de l'origine au point (NombreX|NombreY).

#### Exemple

=ATAN2(-5;9) renvoie 2,07789 radians.

Pour obtenir l'angle en degrés appliquez la fonction DEGRES au résultat.

=DEGRES(ATAN2(12,3;12,3)) renvoie 45. La tangente de 45 degrés est 1.

LibreOffice renvoie 0 pour ATAN2(0;0).

La fonction peut être utilisée pour convertir des coordonnées cartésiennes en coordonnées polaires.

=DEGRES(ATAN2(-8;5)) renvoie φ = 147,9 degrés

## CSC

Renvoie la cosécante de l'angle donné (en radians). La cosécante d'un angle est équivalente à 1 divisé par le sinus de cet angle

Cette fonction est disponible depuis LibreOffice 3.5

#### Syntaxe

CSC(nombre)

Renvoie la cosécante (trigonométrique) de nombre, l'angle en radians.

Pour renvoyer la cosécante d'un angle en degrés, utilisez la fonction RADIANS.

#### Exemple

=CSC(PI()/4) renvoie approximativement 1,4142135624, l'inverse du sinus de PI/4 radians.

=CSC(RADIANS(30)) renvoie 2, la cosécante de 30 degrés.

## CSCH

Renvoie la cosécante hyperbolique d'un nombre.

Cette fonction est disponible depuis LibreOffice 3.5

#### Syntaxe

CSCH(nombre)

Renvoie la cosécante hyperbolique de nombre.

#### Exemple

=CSCH(1) renvoie approximativement 0,8509181282, la cosécante hyperbolique de 1.

## COT

Renvoie la cotangente de l'angle donné (en radians).

#### Syntaxe

COT(nombre)

Renvoie la cotangente (trigonométrique) de nombre, l'angle est en radians.

Pour renvoyer la cotangente d'un angle en degrés, utilisez la fonction RADIANS.

La cotangente d'un angle est équivalente à 1 divisé par la tangente de cet angle.

### Exemples :

=COT(PI()/4) renvoie 1, la cotangente de PI/4 radians.

=COT(RADIANS(45)) renvoie 1, la cotangente de 45 degrés.

## COTH

Renvoie la cotangente hyperbolique d'un nombre donné (angle).

#### Syntaxe

COTH(nombre)

Renvoie la cotangente hyperbolique de nombre.

#### Exemple

=COTH(1) renvoie la cotangente hyperbolique de 1, approximativement 1,3130.

## ACOTH

Renvoie la cotangente hyperbolique inverse du nombre donné.

#### Syntaxe

ACOTH(nombre)

Cette fonction renvoie la cotangente hyperbolique inverse de nombre, c'est à dire le nombre dont la cotangente hyperbolique est nombre.

Il résulte une erreur si le nombre est compris entre -1 et 1 inclus.

#### Exemple

=ACOTH(1,1) renvoie la cotangente hyperbolique inverse de 1,1, approximativement 1,52226.

## ACOT

Renvoie la cotangente inverse (l'arc cotangente) d'un nombre donné.

#### Syntaxe

ACOT(nombre)

Cette fonction renvoie la cotangente trigonométrique inverse de nombre, c'est à dire l'angle (en radians) dont la cotangente est nombre. L'angle renvoyé est entre 0 et PI.

Pour renvoyer un angle en degrés, utilisez la fonction DEGRES.

#### Exemple

=ACOT(1) renvoie 0,785398163397448 (PI/4 radians).

=DEGRES(ACOT(1)) renvoie 45. La tangente de 45 degrés est 1.

## MOD

Renvoie la différence après la division d'un nombre.

#### Syntaxe

MOD(dividende;diviseur)

Pour les arguments de nombres entiers, cette fonction renvoie le dividende modulo le diviseur, c'est à dire le reste quand le dividende est divisé par le diviseur.

Cette fonction est implémentée comme dividende - diviseur * ENT(dividende/diviseur) , et cette formule donne le résultat si l'argument n'est pas un nombre entier.

#### Exemple

=MOD(22;3) renvoie 1, le reste quand 22 est divisé par 3.

=MOD(11,25;2,5) renvoie 1,25.

## FACT

Renvoie la factorielle d'un nombre.

#### Syntaxe

FACT(nombre)

Renvoie nombre!, la factorielle de nombre, calculée comme 1*2*3*4*...*nombre.

=FACT(0) renvoie 1 par définition.

La factorielle d'un nombre négatif renvoie l'erreur "argument invalide".

#### Exemple

=FACT(3) renvoie 6.

=FACT(0) renvoie 1.

## MULTINOMIALE

Renvoie la factorielle de la somme des arguments divisée par le produit des factorielles des arguments.

#### Syntaxe

MULTINOMIALE(nombre(s))

nombre(s) est une liste contenant jusqu'à 30 nombres.

#### Exemple

=MULTINOMIALE(F11:H11) renvoie 1260, si F11 à H11 contiennent les valeurs 2, 3 et 4. Cela correspond à la formule =(2+3+4)!/(2!*3!*4!)

## QUOTIENT

Renvoie la partie entière d'une division.

#### Syntaxe

QUOTIENT(numérateur; dénominateur)

Renvoie la partie du nombre entier du numérateur divisé par le dénominateur.

QUOTIENT est équivalent à ENT(numérateur/dénominateur) pour un numérateur et un dénominateur du même signe, excepté qu'il peut renvoyer des erreurs avec des codes d'erreur différents. Plus généralement, il équivaut à ENT(numérateur/dénominateur/SIGN(numétateur/dénominateur))*SIGN(numérateur/dénominateur).

#### Exemple

=QUOTIENT(11;3) renvoie 3. Le reste 2 est perdu.

## RACINE.PI

Renvoie la racine carrée d'un nombre*PI.

#### Syntaxe

RACINE.PI(nombre)

Renvoie la racine carrée positive de (PI multiplié par nombre).

C'est l'équivalent de RACINE(PI()*nombre).

#### Exemple

=RACINE.PI(2) renvoie la racine carrée de (2PI), approximativement 2,506628.

## RACINE

Renvoie la racine carrée positive d'un nombre.

#### Syntaxe

RACINE(nombre)

Renvoie la racine carrée positive de nombre.

nombre doit être positif.

#### Exemple

=RACINE(16) renvoie 4.

=RACINE(-16) renvoie une erreur argument invalide.

## SEC

Renvoie la sécante d'un angle donné (en radians). La sécante d'un angle est équivalente à 1 divisé par le cosinus de cet angle

Cette fonction est disponible depuis LibreOffice 3.5

#### Syntaxe

SEC(nombre)

Renvoie la sécante (trigonométrique) de nombre, l'angle en radians.

Pour renvoyer la sécante d'un angle en degrés, utilisez la fonction RADIANS.

#### Exemple

=SEC(PI()/4) renvoie approximativement 1.4142135624, l'inverse du cosinus de PI/4 radians.

=SEC(RADIANS(60)) renvoie 2, la sécante de 60 degrés.

## SECH

Renvoie la sécante hyperbolique d'un nombre.

Cette fonction est disponible depuis LibreOffice 3.5

#### Syntaxe

SECH(nombre)

Renvoie la sécante hyperbolique de nombre.

#### Exemple

=SECH(0) renvoie 1, la sécante hyperbolique de 0.

## TAN

Renvoie la tangente de l'angle donné (en radians).

#### Syntaxe

TAN(nombre)

Renvoie la tangente (trigonométrique) de Nombre, l'angle est en radians.

Pour renvoyer la tangente d'un angle en degrés, utilisez la fonction RADIANS.

#### Exemple

=TAN(PI()/4) renvoie 1, la tangente de PI/4 radians.

=TAN(RADIANS(45)) renvoie 1, la tangente de 45 degrés.

## TANH

Renvoie la tangente hyperbolique d'un nombre.

#### Syntaxe

TANH(nombre)

Renvoie la tangente hyperbolique de Nombre.

#### Exemple

=TANH(0) renvoie 0, la tangente hyperbolique de 0.

## ATANH

Renvoie la tangente hyperbolique inverse d'un nombre.

#### Syntaxe

ATANH(nombre)

Cette fonction renvoie la tangente hyperbolique inverse de nombre, c'est à dire le nombre dont la tangente hyperbolique est nombre.

Le nombre doit obéir à la condition -1 < nombre < 1.

#### Exemple

=ATANH(0) renvoie 0.

## ATAN

Renvoie la tangente trigonométrique inverse d'un nombre.

#### Syntaxe

ATAN(nombre)

Cette fonction renvoie la tangente trigonométrique inverse de nombre, c'est à dire l'angle (en radians) dont la tangente est nombre. L'angle renvoyé est entre -PI/2 et PI/2.

Pour renvoyer un angle en degrés, utilisez la fonction DEGRES.

#### Exemple

=ATAN(1) renvoie 0,785398163397448 (PI/4 radians).

=DEGRES(ATAN(1)) renvoie 45. La tangente de 45 degrés est 1.

## ABS

Renvoie la valeur absolue d'un nombre.

#### Syntaxe

ABS(nombre)

nombre est le nombre dont la valeur absolue est à calculer. La valeur absolue d'un nombre est sa valeur sans le signe +/-.

#### Exemple

=ABS(-56) renvoie 56.

=ABS(12) renvoie 12.

=ABS(0) renvoie 0.

## COS

Renvoie le cosinus de l'angle donné (en radians).

#### Syntaxe

COS(nombre)

nombre est la valeur dont le cosinus est à calculer, l'angle en radians.

Pour renvoyer le cosinus d'un angle en degrés, utilisez la fonction RADIANS.

#### Exemple

=COS(PI()*2) renvoie 1, le cosinus de 2*PI radians.

=COS(RADIANS(60)) renvoie 0,5, le cosinus de 60 degrés.

## COSH

Renvoie le cosinus hyperbolique d'un nombre.

#### Syntaxe

COSH(nombre)

Renvoie le cosinus hyperbolique de nombre.

#### Exemple

=COSH(0) renvoie 1, le cosinus hyperbolique de 0.

## ACOSH

Renvoie le cosinus hyperbolique inverse d'un nombre.

#### Syntaxe

ACOSH(nombre)

La fonction renvoie le cosinus hyperbolique inverse de nombre, c'est à dire le nombre dont le cosinus hyperbolique est nombre.

Nombre doit être supérieur ou égal à 1.

#### Exemple

=ACOSH(1) renvoie 0.

=ACOSH(COSH(4)) renvoie 4.

## ACOS

Renvoie le cosinus trigonométrique inverse d'un nombre.

#### Syntaxe

ACOS(nombre)

Cette fonction renvoie le cosinus trigonométrique inverse de nombre, c'est à dire l'angle (en radians) dont le cosinus est nombre. L'angle renvoyé est entre 0 et PI.

Pour renvoyer un angle en degrés, utilisez la fonction DEGRES.

#### Exemple

=ACOS(-1) renvoie 3,14159265358979 (PI radians)

=DEGRES(ACOS(0,5)) renvoie 60. Le cosinus de 60 degrés est 0,5.

## LOG

Renvoie le logarithme d'un nombre dans la base spécifiée.

#### Syntaxe

LOG(nombre;base)

nombre correspond à la valeur dont le logarithme est à calculer.

base (falcultatif) est la base pour le calcul du logarithme. Si omis, c'est la Base 10 qui est supposée.

#### Exemple

=LOG(10;3) renvoie le logarithme de base 3 de 10 (approximativement 2,0959).

=LOG(7^4;7) renvoie 4.

## LOG10

Renvoie le logarithme en base 10 d'un nombre.

#### Syntaxe

LOG10(nombre)

Renvoie le logarithme en base 10 du nombre.

#### Exemple

=LOG10(5) renvoie le logarithme en base 10 de 5 (approximativement 0,69897).

## LN

Renvoie le logarithme naturel à partir de la constante e d'un nombre. La constante e a une valeur approximative de 2,71828182845904.

#### Syntaxe

LN(nombre)

nombre est la valeur dont vous souhaitez calculer le logarithme népérien.

#### Exemple

=LN(3) renvoie le logarithme népérien de 3 (approximativement 1,0986).

=LN(EXP(321)) renvoie 321.

## COMBIN

Renvoie le nombre de combinaisons pour des éléments sans répétition.

#### Syntaxe

COMBIN(nombre1;nombre2)

nombre1 est le nombre d'éléments dans l'ensemble.

nombre2 est le nombre d'éléments à choisir dans l'ensemble.

COMBIN renvoie le nombre de façon ordonné de choisir ces éléments. Par exemple, s'il y a 3 éléments A, B et C dans un ensemble, vous pouvez choisir 2 éléments de 3 façons différentes : AB, AC et BC.

COMBIN implémente la formule : nombre1!/(nombre2!*(nombre1-nombre2)!)

#### Exemple

=COMBIN(3;2) renvoie 3.

## COMBINA

Renvoie le nombre de combinaisons pour un sous ensemble d'éléments incluant les répétitions.

#### Syntaxe

COMBINA(nombre1;nombre2)

nombre1 est le nombre d'éléments dans l'ensemble.

nombre2 est le nombre d'éléments à choisir dans l'ensemble.

COMBINA renvoie le nombre de façons uniques de choisir ces éléments, où l'ordre du choix est sans importance et les répétions d'éléments sont autorisées. Par exemple, s'il y a 3 éléments A, B et C dans un ensemble, vous pouvez choisir 2 éléments de 6 façons différentes, nommément : AA, AB, AC, BB, BC et CC.

COMBINA implémente la formule : (nombre1+nombre2-1)!/(nombre2!(nombre1-1)!)

#### Exemple

=COMBINA(3;2) renvoie 6.

## PGCD_EXCEL2003

Renvoie le plus grand diviseur commun d'une liste de nombres.

Les fonctions dont les noms se terminent par _ADD ou _EXCEL2003 renvoient le même résultat que les fonctions correspondantes Microsoft Excel 2003 sans le suffixe. Utilisez les fonctions sans suffixe pour obtenir des résultats basés sur les standards internationaux.

#### Syntaxe

PGCD_EXCEL2003(Nombre(s))

nombre(s) est une liste contenant jusqu'à 30 nombres.

#### Exemple

=PGCD_EXCEL2003(5;15;25) renvoie 5.

## PGCD

Renvoie le plus grand diviseur commun de plusieurs nombres entiers.

Le plus grand diviseur commun est l'entier positif le plus grand permettant de diviser sans reste chacun des entiers donnés.

#### Syntaxe

PGCD(nombre_entier_1;nombre_entier_2;...;nombre_entier_30)

nombre_entier1 à 30 représente jusqu'à 30 nombres entiers dont le plus grand diviseur commun doit être calculé.

#### Exemple

=PGCD(16;32;24) donne 8 comme résultat, parce que 8 est le plus grand nombre qui peut diviser 16, 24 et 32 sans reste.

=PGCD(B1:B3) où les cellules B1, B2, B3 contiennent 9, 12, 9 renvoie 3.

## PPCM

Renvoie le plus petit multiple commun d'un ou de plusieurs nombres entiers.

#### Syntaxe

PPCM(nombre_entier1;nombre_entier2;...;nombre_entier30)

nombre_entier1 à 30 représente jusqu'à 30 nombres entiers dont le plus petit commun multiple doit être calculé.

#### Exemple

Si vous saisissez les nombres 512;1024 et 2000 dans les zones de textes de nombres entiers 1;2 et 3, 128000 sera le résultat renvoyé.

## SIGNE

Renvoie le signe d'un nombre. Renvoie 1 si le nombre est positif, -1 si négatif et 0 si zéro.

#### Syntaxe

SIGNE(nombre)

nombre est le nombre dont le signe doit être déterminé.

#### Exemple

=SIGNE(3,4) renvoie 1.

=SIGNE(-4,5) renvoie -1.

## SIN

Renvoie le sinus du nombre donné (en radians).

#### Syntaxe

SIN(nombre)

Renvoie le sinus (trigonométrique) de nombre, l'angle est en radians.

Pour renvoyer le sinus d'un angle en degrés, utilisez la fonction RADIANS.

#### Exemple

=SIN(PI()/2) renvoie 1, le sinus de PI/2 radians.

=SIN(RADIANS(30)) renvoie 0,5, le sinus de 30 degrés.

## SINH

Renvoie le sinus hyperbolique d'un nombre.

#### Syntaxe

SINH(nombre)

Renvoie le sinus hyperbolique de Nombre.

#### Exemple

=SINH(0) renvoie 0, le sinus hyperbolique de 0.

## ASINH

Renvoie le sinus hyperbolique inverse d'un nombre.

#### Syntaxe

ASINH(nombre)

Cette fonction renvoie le sinus hyperbolique inverse de nombre, c'est à dire le nombre dont le sinus hyperbolique est nombre.

#### Exemple

=ASINH(-90) renvoie approximativement -5,1929877.

=ASINH(SINH(4)) renvoie 4.

## ASIN

Renvoie le sinus trigonométrique inverse d'un nombre.

#### Syntaxe

ASIN(nombre)

Cette fonction renvoie le sinus trigonométrique inverse de nombre, c'est à dire l'angle (en radians) dont le sinus est nombre. L'angle renvoyé est entre -PI/2 et + PI/2.

Pour renvoyer un angle en degrés, utilisez la fonction DEGRES.

#### Exemple

=ASIN(0) renvoie 0.

=ASIN(1) renvoie 1,5707963267949 (PI/2 radians).

=DEGRES(ASIN(0,5)) renvoie 30. Le sinus de 30 degrés est 0,5.

## ALEA

Renvoie un nombre aléatoire compris entre 0 et 1.

#### Syntaxe

ALEA()

Cette fonction produit un nouveau nombre aléatoire à chaque fois que Calc recalcule. Pour forcer Calc à recalculer manuellement, appuyez sur F9.

Pour générer un nombre aléatoire qui n'est jamais recalculé, copiez les cellules contenant =ALEA() et utilisez Édition - Collage spécial (avec Tout coller et Formules non cochés et Nombres coché).

#### Exemple

=ALEA() renvoie un nombre entre 0 et 1.

## ALEA.ENTRE.BORNES

Renvoie un nombre entier aléatoire compris dans une plage spécifiée.

#### Syntaxe

ALEA.ENTRE.BORNES(minimum;maximum)

Renvoie un nombre entier aléatoire entre les nombres entiers minimum et maximum (tous deux inclusifs).

Cette fonction produit un nouveau nombre aléatoire à chaque fois que Calc recalcule. Pour forcer Calc à recalculer manuellement, appuyez sur F9.

Pour générer des nombres aléatoires qui ne sont jamais recalculés, copiez les cellules contenant cette fonction et utilisez Édition - Collage spécial (avec Tout coller et Formules non cochées et Nombres coché).

#### Exemple

=ALEA.ENTRE.BORNES(20;30) renvoie un nombre entier entre 20 et 30.

## PUISSANCE

Renvoie un nombre élevé à un autre nombre.

#### Syntaxe

PUISSANCE (base; exposant)

Renvoie la base élevée à la puissance de exposant.

On obtiendra le même résultat en utilisant l'opérateur d'exposant ^ :

base^exposant

#### Exemple

=PUISSANCE(4;3) renvoie 64, qui correspond à 4 à la puissance 3.

=4^3 renvoie aussi 4 à la puissance 3.

## SOMME.CARRES

Si vous souhaitez calculer la somme des carrés de ces nombres (dont le total correspondra aux carrés des arguments), saisissez-les dans les champs de texte.

#### Syntaxe

SOMMES.CARRES(nombre_1;nombre_2;...;nombre_30)

nombre_1 à 30 représente jusqu'à 30 arguments dont la somme des carrés doit être calculée.

#### Exemple

Si vous saisissez les nombres 2 ; 3 et 4 dans les zones de texte nombre 1; 2 et 3, 29 est le résultat renvoyé.

## TRONQUE

Tronque un nombre en supprimant ses décimales.

#### Syntaxe

TRONQUE(nombre;nombre)

Renvoie le nombre avec tout au plus le nombre de décimales. Les décimales en plus sont simplement supprimées, sans tenir compte du signe.

TRONQUE(nombre;0) se comporte comme ENT(nombre) pour les nombres positifs, mais arrondit effectivement autour de zéro pour les nombres négatifs.

Le nombre de décimales visibles du résultat est spécifié dans LibreOffice - Préfrences Outils - Options - LibreOffice Calc - Calcul.

#### Exemple

=TRONQUE(1,239;2) renvoie 1,23. Le 9 est perdu.

=TRONQUE(-1,234999;3) renvoie -1,234. Tous les 9 sont perdus.

Rubriques connexes

Fonctions par catégories